[arch-commits] Commit in haskell-vty/repos (2 files)

[Felix Yan]

    Date: Monday, August 8, 2022 @ 16:38:50
  Author: felixonmars
Revision: 1261315

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-vty/repos/community-staging-x86_64/
  haskell-vty/repos/community-staging-x86_64/PKGBUILD
    (from rev 1261314, haskell-vty/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-vty/repos/community-staging-x86_64/PKGBUILD (from rev 1261314, haskell-vty/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-08 16:38:50 UTC (rev 1261315)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=vty
+pkgname=haskell-vty
+pkgver=5.36
+pkgrel=4
+pkgdesc="A simple terminal UI library"
+url="https://github.com/jtdaugherty/vty"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-blaze-builder' 'haskell-microlens'
+         'haskell-microlens-mtl' 'haskell-microlens-th' 'haskell-hashable' 'haskell-parallel'
+         'haskell-utf8-string' 'haskell-vector')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-smallcheck'
+             'haskell-quickcheck-assertions' 'haskell-test-framework'
+             'haskell-test-framework-smallcheck' 'haskell-test-framework-hunit' 'haskell-random'
+             'haskell-string-qq')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('d9392086bc68d6f805ab23fe2f88f217c6c8ab7debbb954fb0713c028e536c5c6bb10d7c7cd4a701e3b88d867b5fefcc17e73515668378fc043b0b4de8993aaa')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}