[arch-commits] Commit in (3 files)

[Maxime Gauduin]

    Date: Tuesday, August 9, 2022 @ 09:21:26
  Author: alucryd
Revision: 1263496

add python-bleak for home-assistant

Added:
  python-bleak/
  python-bleak/trunk/
  python-bleak/trunk/PKGBUILD

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Added: python-bleak/trunk/PKGBUILD
===================================================================
--- python-bleak/trunk/PKGBUILD	                        (rev 0)
+++ python-bleak/trunk/PKGBUILD	2022-08-09 09:21:26 UTC (rev 1263496)
@@ -0,0 +1,43 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Francesco Minnocci <ascoli.minnocci at gmail.com>
+
+pkgname=python-bleak
+pkgver=0.15.1
+pkgrel=1
+pkgdesc='Bluetooth Low Energy platform Agnostic Klient for Python'
+arch=(any)
+url=https://github.com/hbldh/bleak
+license=(MIT)
+depends=(
+  python
+  python-async-timeout
+  python-dbus-next
+  python-service-identity
+  python-typing_extensions
+)
+makedepends=(
+  bluez-utils
+  git
+  python-setuptools
+)
+_tag=ac17549780b1540420354db07bfc640b35492bcd
+source=(git+https://github.com/hbldh/bleak.git#tag=${_tag})
+b2sums=(SKIP)
+
+pkgver() {
+  cd bleak
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cd bleak
+  python setup.py build
+}
+
+package() {
+  cd bleak
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/python-bleak/
+}
+
+# vim: ts=2 sw=2 et: