[arch-commits] Commit in waybar/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Brett Cornwall ainola at gemini.archlinux.org
Tue Aug 9 14:41:26 UTC 2022


    Date: Tuesday, August 9, 2022 @ 14:41:26
  Author: ainola
Revision: 1263573

archrelease: copy trunk to staging-x86_64

Added:
  waybar/repos/staging-x86_64/
  waybar/repos/staging-x86_64/PKGBUILD
    (from rev 1263572, waybar/trunk/PKGBUILD)

----------+
 PKGBUILD |   73 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)

Copied: waybar/repos/staging-x86_64/PKGBUILD (from rev 1263572, waybar/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-08-09 14:41:26 UTC (rev 1263573)
@@ -0,0 +1,73 @@
+# Maintainer: Brett Cornwall <ainola at archlinux.org>
+# Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
+
+pkgname=waybar
+pkgver=0.9.13
+pkgrel=2
+pkgdesc='Highly customizable Wayland bar for Sway and Wlroots based compositors'
+arch=('x86_64')
+url="https://github.com/Alexays/Waybar/"
+license=('MIT')
+depends=(
+    'gtkmm3'
+    'libjsoncpp.so'
+    'libsigc++'
+    'fmt'
+    'wayland'
+    'libdate-tz.so'
+    'libspdlog.so'
+    'gtk-layer-shell'
+    'libupower-glib.so'
+    'upower'
+    'libevdev'
+    'libpulse'
+    'libnl'
+    'libappindicator-gtk3'
+    'libdbusmenu-gtk3'
+    'libmpdclient'
+    'libsndio.so'
+    'libxkbcommon'
+)
+makedepends=(
+    'cmake'
+    'catch2'
+    'meson'
+    'scdoc' # For generating manpages
+    'wayland-protocols'
+)
+backup=(
+    etc/xdg/waybar/config
+    etc/xdg/waybar/style.css
+)
+optdepends=(
+    'otf-font-awesome: Icons in the default configuration'
+)
+source=(
+    "$pkgname-$pkgver.tar.gz::https://github.com/Alexays/Waybar/archive/$pkgver.tar.gz"
+    "https://patch-diff.githubusercontent.com/raw/Alexays/Waybar/pull/1617.patch"
+)
+sha256sums=('9e6553274ce3013d2be9912f975287efe4dfd38de4e335db43a73aff2a3b0a34'
+            'bedf05c1aeecd9fad517bc91583d3054de97b07e92c63e75220b16f728f10112')
+
+prepare() {
+    cd "Waybar-$pkgver"
+    # Fix fmt 9 compilation issues. This is on master but not yet part of a
+    # release
+    patch -p1 < ../1617.patch
+}
+
+build() {
+    cd "Waybar-$pkgver"
+    meson --prefix=/usr \
+          --buildtype=plain \
+          --auto-features=enabled \
+          --wrap-mode=nodownload \
+          build
+    ninja -C build
+}
+
+package() {
+    cd "Waybar-$pkgver"
+    DESTDIR="$pkgdir" ninja -C build install
+    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+}



More information about the arch-commits mailing list