[arch-commits] Commit in haskell-clash-prelude/repos (2 files)

[Felix Yan]

    Date: Tuesday, August 9, 2022 @ 17:24:02
  Author: felixonmars
Revision: 1264151

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-clash-prelude/repos/community-staging-x86_64/
  haskell-clash-prelude/repos/community-staging-x86_64/PKGBUILD
    (from rev 1264150, haskell-clash-prelude/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: haskell-clash-prelude/repos/community-staging-x86_64/PKGBUILD (from rev 1264150, haskell-clash-prelude/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-09 17:24:02 UTC (rev 1264151)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=clash-prelude
+pkgname=haskell-clash-prelude
+pkgver=1.6.3
+pkgrel=5
+pkgdesc="Clash: a functional hardware description language - Prelude library"
+url="https://github.com/clash-lang/clash-prelude"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-arrows' 'haskell-constraints' 'haskell-data-binary-ieee754'
+         'haskell-data-default-class' 'haskell-extra' 'haskell-ghc-typelits-extra'
+         'haskell-ghc-typelits-knownnat' 'haskell-ghc-typelits-natnormalise' 'haskell-half'
+         'haskell-hashable' 'haskell-interpolate' 'haskell-lens' 'haskell-quickcheck'
+         'haskell-recursion-schemes' 'haskell-reflection' 'haskell-singletons'
+         'haskell-th-abstraction' 'haskell-th-lift' 'haskell-th-orphans' 'haskell-type-errors'
+         'haskell-uniplate' 'haskell-vector')
+makedepends=('ghc' 'uusi' 'haskell-doctest-parallel' 'haskell-hedgehog' 'haskell-hint'
+             'haskell-quickcheck-classes-base' 'haskell-tasty' 'haskell-tasty-hedgehog'
+             'haskell-tasty-hunit' 'haskell-tasty-quickcheck' 'haskell-tasty-th')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('bc8ab36af16b78bee39f0229f824e81f043034ae7acba1b4474f2781d3641352992be497802cdfd2877a23335ec1a87a7c726b9a236ee568f7d41a09f471368e')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    uusi -u lens $_hkgname.cabal
+    gen-setup
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    # TODO
+    runhaskell Setup test --show-details=direct || warning "Tests failed"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}