[arch-commits] Commit in bear/repos (2 files)

[George Rawlinson]

    Date: Wednesday, August 10, 2022 @ 07:42:47
  Author: grawlinson
Revision: 1265029

archrelease: copy trunk to community-staging-x86_64

Added:
  bear/repos/community-staging-x86_64/
  bear/repos/community-staging-x86_64/PKGBUILD
    (from rev 1265028, bear/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: bear/repos/community-staging-x86_64/PKGBUILD (from rev 1265028, bear/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-10 07:42:47 UTC (rev 1265029)
@@ -0,0 +1,59 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Yiyao Yu <yuydevel at protonmail dot com>
+# Contributor: Moritz Lipp <mlq at pwmt.org>
+
+pkgname=bear
+pkgver=3.0.20
+pkgrel=2
+pkgdesc='A tool to generate compilation database for clang tooling'
+arch=('x86_64')
+url='https://github.com/rizsotto/Bear'
+license=('GPL3')
+depends=(
+  'grpc'
+  'libgrpc++.so'
+  'fmt'
+  'spdlog'
+  'nlohmann-json'
+  'abseil-cpp'
+  'protobuf'
+  'openssl'
+  'c-ares'
+  're2'
+)
+makedepends=(
+  'git'
+  'cmake'
+  'gtest'
+  'python'
+  'llvm'
+)
+_commit='67d5a349dd55125a6df3ec437a0e0a09c3f92c56'
+source=("$pkgname::git+$url.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags
+}
+
+# XXX if this is moved to build, tests fail.
+# there must be some environment variables that
+# are discarded inbetween functions.
+prepare() {
+  cmake \
+    -B build \
+    -S "$pkgname" \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_SYSCONFDIR=/etc \
+    -DCMAKE_INSTALL_LIBEXECDIR="lib/$pkgname"
+}
+
+build() {
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}