[arch-commits] Commit in libinih/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Maxime Gauduin
alucryd at gemini.archlinux.org
Thu Aug 11 09:32:01 UTC 2022
Date: Thursday, August 11, 2022 @ 09:32:01
Author: alucryd
Revision: 452554
archrelease: copy trunk to testing-x86_64
Added:
libinih/repos/testing-x86_64/
libinih/repos/testing-x86_64/PKGBUILD
(from rev 452553, libinih/trunk/PKGBUILD)
----------+
PKGBUILD | 45 +++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 45 insertions(+)
Copied: libinih/repos/testing-x86_64/PKGBUILD (from rev 452553, libinih/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2022-08-11 09:32:01 UTC (rev 452554)
@@ -0,0 +1,45 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Alberto Oporto Ames <otreblain at gmail.com>
+
+pkgname=libinih
+pkgver=56
+pkgrel=1
+pkgdesc='A simple .INI file parser written in C'
+arch=(x86_64)
+url=https://github.com/benhoyt/inih
+license=(BSD)
+depends=(
+ gcc-libs
+ glibc
+)
+makedepends=(
+ git
+ meson
+)
+provides=(
+ libinih.so
+ libINIReader.so
+)
+_tag=5e1d9e2625842dddb3f9c086a50f22e4f45dfc2b
+source=(git+https://github.com/benhoyt/inih.git#tag=${_tag})
+b2sums=(SKIP)
+
+pkgver() {
+ cd inih
+ git describe --tags | sed 's/^r//'
+}
+
+build() {
+ arch-meson inih build \
+ -Ddefault_library=shared \
+ -Ddistro_install=true \
+ -Dwith_INIReader=true
+ meson compile -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" meson install -C build
+ install -Dm 644 inih/LICENSE.txt -t "${pkgdir}"/usr/share/licenses/libinih/
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list