[arch-commits] Commit in baresip/repos (2 files)

[Alexander Epaneshnikov]

    Date: Thursday, August 11, 2022 @ 22:13:53
  Author: alex19ep
Revision: 1265301

archrelease: copy trunk to community-staging-x86_64

Added:
  baresip/repos/community-staging-x86_64/
  baresip/repos/community-staging-x86_64/PKGBUILD
    (from rev 1265300, baresip/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: baresip/repos/community-staging-x86_64/PKGBUILD (from rev 1265300, baresip/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-11 22:13:53 UTC (rev 1265301)
@@ -0,0 +1,56 @@
+# Maintainer: Alexander Epaneshnikov <alex19ep at archlinux.org>
+# Contributor: Andrew Sun <adsun701 at gmail dot com>
+# Contributor: Dmitrij D. Czarkoff <czarkoff at gmail dot com>
+
+pkgname=baresip
+pkgver=2.6.0
+pkgrel=1
+pkgdesc="portable and modular SIP User-Agent with audio and video support"
+arch=('x86_64')
+url="https://github.com/baresip/baresip"
+license=('BSD')
+depends=(libre.so librem.so openssl)
+optdepends=('libfdk-aac: AAC audio codec'
+            'alsa-lib: ALSA audio driver'
+            'opencore-amr: Adaptive Multi-Rate (AMR) audio codec'
+            'aom: (av1 module}'
+            'codec2: CODEC2 low-bitrate speech audio codec'
+            'ffmpeg: (avcodec, avformat, h265 modules)'
+            'gsm: (gsm module)'
+            'gst-plugins-bad: (gst1, gst_video1 modules)'
+            'gst-plugins-base: (gst1, gst_video1 modules)'
+            'gst-plugins-good: (gst1, gst_video1 modules)'
+            'gst-plugins-ugly: (gst1, gst_video1 modules)'
+            'gtk3: gtk+ user interface'
+            'jack2: JACK Audio Connection Kit audio driver'
+            'lame: MPA audio codec'
+            'libvpx: (vpx module)'
+            'libsndfile: (sndfile module)'
+            'libpng: Snapshot video module'
+            'libpulse: Pulseaudio audio driver'
+            'libx11: (x11, x11grab modules)'
+            'mpg123: (rst module)'
+            'opus: (opus module)'
+            'portaudio: Portaudio audio driver'
+            'sdl2: (sdl2 module)'
+            'spandsp: (g722, g726,plc modules)'
+            'speexdsp: (speex_aec, speex_pp modules)'
+            'sndio: sndio audio driver'
+            'v4l-utils: (v4l2 module)')
+makedepends=(${optdepends[@]/%:*/} python)
+source=("${pkgname}-${pkgver}.tar.gz"::"https://github.com/baresip/baresip/archive/v${pkgver}.tar.gz")
+sha256sums=('86e04cef08828515cc9e690cf0f37d8b0f1f69c6d84bd8eea7a70df05b0aca76')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  export LFLAGS=$LDFLAGS
+  make RELEASE=1 V=1 USE_GST= USE_GST_VIDEO= DESTDIR="/usr" PREFIX="/usr"
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  export LFLAGS=$LDFLAGS
+  make RELEASE=1 USE_GST= USE_GST_VIDEO= PREFIX="/usr" \
+    DESTDIR="$pkgdir/" install
+  install -vDm644 docs/COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
+}