[arch-commits] Commit in libharu/repos (2 files)

[Frederik Schwan]

    Date: Friday, August 12, 2022 @ 18:15:59
  Author: freswa
Revision: 1265637

archrelease: copy trunk to community-testing-x86_64

Added:
  libharu/repos/community-testing-x86_64/
  libharu/repos/community-testing-x86_64/PKGBUILD
    (from rev 1265636, libharu/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: libharu/repos/community-testing-x86_64/PKGBUILD (from rev 1265636, libharu/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-08-12 18:15:59 UTC (rev 1265637)
@@ -0,0 +1,38 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: Auguste <auguste at gmail.com>
+# Contributor: Jose Negron <josenj.arch at mailnull.com>
+
+pkgname=libharu
+pkgver=2.4.0
+pkgrel=1
+pkgdesc="C library for generating PDF documents"
+arch=(x86_64)
+url="https://github.com/libharu/libharu"
+license=(custom:ZLIB)
+depends=(libpng zlib)
+makedepends=(cmake)
+source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('96521b6ee65c256d8d2322dc4abe8f6a93746cd3bb6ed9a1cdeb9c365acf28069f6f09dd7104196ea1cd0cc69eafbe6a6c922590e53fff7ea8e4c7d56dbc5552')
+
+prepare() {
+  sed -i "s#add_library(haru#add_library(hpdf#" ${pkgname}-${pkgver}/src/CMakeLists.txt
+  sed -i "s#target_link_libraries (haru#target_link_libraries (hpdf#" ${pkgname}-${pkgver}/src/CMakeLists.txt
+}
+
+build() {
+  cmake -B build -S ${pkgname}-${pkgver} \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DLIBHPDF_STATIC=OFF
+  make -C build
+}
+
+package() {
+  make -C build DESTDIR="${pkgdir}" install
+  install -Dm755 build/src/libhpdf.so "${pkgdir}"/usr/lib/libhpdf.so
+  # License
+  install -Dm644 ${pkgname}-${pkgver}/LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+  # Remove some uneeded wrongly installed files
+  rm "${pkgdir}"/usr/{CHANGES,INSTALL,README.md}
+  rm -r "${pkgdir}"/usr/bindings
+}