[arch-commits] Commit in rsync/repos (4 files)

[Christian Hesse]

    Date: Sunday, August 14, 2022 @ 19:58:27
  Author: eworm
Revision: 452711

archrelease: copy trunk to testing-x86_64

Added:
  rsync/repos/testing-x86_64/
  rsync/repos/testing-x86_64/PKGBUILD
    (from rev 452710, rsync/trunk/PKGBUILD)
  rsync/repos/testing-x86_64/keys/
  rsync/repos/testing-x86_64/rsyncd.conf
    (from rev 452710, rsync/trunk/rsyncd.conf)

-------------+
 PKGBUILD    |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 rsyncd.conf |   10 ++++++++++
 2 files changed, 66 insertions(+)

Copied: rsync/repos/testing-x86_64/PKGBUILD (from rev 452710, rsync/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-08-14 19:58:27 UTC (rev 452711)
@@ -0,0 +1,56 @@
+# Maintainer: Christian Hesse <mail at eworm.de>
+
+pkgname=rsync
+_tag='001cc050f46d05cb0487359ed5101018da14a5a3' # git rev-parse v${pkgver}
+pkgver=3.2.5
+pkgrel=1
+pkgdesc='A fast and versatile file copying tool for remote and local files'
+arch=('x86_64')
+url='https://rsync.samba.org/'
+license=('GPL3')
+depends=('acl' 'libacl.so' 'lz4' 'openssl' 'perl' 'popt' 'xxhash' 'libxxhash.so'
+         'zlib' 'zstd')
+makedepends=('git' 'python-commonmark')
+options=('debug')
+backup=('etc/rsyncd.conf'
+        'etc/xinetd.d/rsync')
+validpgpkeys=('0048C8B026D4C96F0E589C2F6C859FB14B96A8C5') # Wayne Davison <wayned at users.sourceforge.net>
+source=("git+https://github.com/WayneD/rsync#tag=${_tag}?signed"
+        'rsyncd.conf')
+sha256sums=('SKIP'
+            '733ccb571721433c3a6262c58b658253ca6553bec79c2bdd0011810bb4f2156b')
+
+prepare() {
+	cd "$srcdir/rsync"
+
+	git merge --ff-only 'cff8f044776c5143a5b270969d4bb0f1fea8b017'
+}
+
+build() {
+	cd "$srcdir/rsync"
+
+	./configure \
+		--prefix=/usr \
+		--disable-debug \
+		--with-included-popt=no \
+		--with-included-zlib=no
+	make
+}
+
+check() {
+	cd "$srcdir/rsync"
+
+	make test
+}
+
+package() {
+	cd "$srcdir/rsync"
+
+	make DESTDIR="$pkgdir" install
+	install -Dm0644 ../rsyncd.conf "$pkgdir/etc/rsyncd.conf"
+	install -Dm0644 packaging/lsb/rsync.xinetd "$pkgdir/etc/xinetd.d/rsync"
+	install -Dm0644 packaging/systemd/rsync.service "$pkgdir/usr/lib/systemd/system/rsyncd.service"
+	install -Dm0644 packaging/systemd/rsync.socket "$pkgdir/usr/lib/systemd/system/rsyncd.socket"
+	install -Dm0644 packaging/systemd/rsync at .service "$pkgdir/usr/lib/systemd/system/rsyncd at .service"
+	install -Dm0755 support/rrsync "$pkgdir/usr/lib/rsync/rrsync"
+}

Copied: rsync/repos/testing-x86_64/rsyncd.conf (from rev 452710, rsync/trunk/rsyncd.conf)
===================================================================
--- testing-x86_64/rsyncd.conf	                        (rev 0)
+++ testing-x86_64/rsyncd.conf	2022-08-14 19:58:27 UTC (rev 452711)
@@ -0,0 +1,10 @@
+uid = nobody
+gid = nobody
+use chroot = no
+max connections = 4
+syslog facility = local5
+pid file = /run/rsyncd.pid
+
+[ftp]
+        path = /srv/ftp
+        comment = ftp area