[arch-commits] Commit in git-delta/repos (2 files)

[George Rawlinson]

    Date: Tuesday, August 16, 2022 @ 23:06:41
  Author: grawlinson
Revision: 1266683

archrelease: copy trunk to community-staging-x86_64

Added:
  git-delta/repos/community-staging-x86_64/
  git-delta/repos/community-staging-x86_64/PKGBUILD
    (from rev 1266682, git-delta/trunk/PKGBUILD)

----------+
 PKGBUILD |   69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

Copied: git-delta/repos/community-staging-x86_64/PKGBUILD (from rev 1266682, git-delta/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-16 23:06:41 UTC (rev 1266683)
@@ -0,0 +1,69 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Kr1ss $(echo \<kr1ss+x-yandex+com\>|sed s/\+/./g\;s/\-/@/)
+# Contributor: ccorn
+
+pkgname=git-delta
+_pkgname=delta
+pkgver=0.13.0
+pkgrel=2
+pkgdesc='Syntax-highlighting pager for git and diff output'
+arch=('x86_64')
+url='https://github.com/dandavison/delta'
+license=('MIT')
+depends=('libgit2' 'libgit2.so')
+makedepends=('rust' 'mdbook')
+checkdepends=('git')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+sha512sums=('d7dbaaab345ef3a8db04fb7ce6337d4cb104d148a069d4b47ffbe46c73ebff197a083a7ac061b51196754a5046dcfc1f71b633e8bfead1ebd9324cc624ba4313')
+b2sums=('85fc3a9d1a661b8bc6ba6e9996a4d93d2a669df956f9ca4387b1bb3e2ec30bec7f48a485ff4cd9421239667147f28bd549abe0267fd28e0463b68647bbc7057b')
+
+prepare() {
+  cd "$_pkgname-$pkgver"
+
+  # download dependencies
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$_pkgname-$pkgver"
+
+  # https://archlinux.org/todo/lto-fat-objects/
+  CFLAGS+=' -ffat-lto-objects'
+
+  # binary
+  cargo build --frozen --release --all-features
+
+  # html manual
+  cd manual
+  mdbook build --dest-dir html
+}
+
+check() {
+  cd "$_pkgname-$pkgver"
+  # some tests hang for 60+ seconds, find out why
+  # took my machine ~ 470 seconds
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "$_pkgname-$pkgver"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" target/release/delta
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+
+  # shell auto-completions
+  install -vDm644 etc/completion/completion.bash \
+    "$pkgdir/usr/share/bash-completion/completions/$_pkgname"
+  install -vDm644 etc/completion/completion.zsh \
+    "$pkgdir/usr/share/zsh/site-functions/_$_pkgname"
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+
+  # html manual
+  cp -r manual/html "$pkgdir/usr/share/doc/$pkgname"
+}