[arch-commits] Commit in ostree/repos (3 files)

[Jan Steffens]

    Date: Wednesday, August 17, 2022 @ 22:12:12
  Author: heftig
Revision: 453074

archrelease: copy trunk to testing-x86_64

Added:
  ostree/repos/testing-x86_64/
  ostree/repos/testing-x86_64/PKGBUILD
    (from rev 453071, ostree/trunk/PKGBUILD)
  ostree/repos/testing-x86_64/keys/

----------+
 PKGBUILD |   81 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 81 insertions(+)

Copied: ostree/repos/testing-x86_64/PKGBUILD (from rev 453071, ostree/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-08-17 22:12:12 UTC (rev 453074)
@@ -0,0 +1,81 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Mirco Tischler <mt-ml at gmx dot de>
+
+pkgname=ostree
+_commit=15740d042c9c5258a1c082b5e228cf6f115edbb0  # tags/v2022.5^0
+pkgver=2022.5
+pkgrel=3
+pkgdesc="Operating system and container binary deployment and upgrades"
+url="https://ostreedev.github.io/ostree/"
+arch=(x86_64)
+license=(GPL)
+depends=(fuse3 glibc libgpg-error libsodium util-linux openssl xz zlib)
+makedepends=(avahi e2fsprogs git glib2 gobject-introspection gpgme gtk-doc
+             libarchive libsoup libxslt mkinitcpio python systemd)
+checkdepends=(cpio elfutils gjs parallel python-yaml syslinux)
+options=(debug)
+source=(
+  "git+https://github.com/ostreedev/ostree#commit=$_commit"
+  git+https://github.com/mendsley/bsdiff
+  git+https://gitlab.gnome.org/GNOME/libglnx.git
+)
+b2sums=('SKIP'
+        'SKIP'
+        'SKIP')
+# upstream ticket about chain of trust:
+# https://github.com/ostreedev/ostree/issues/2349
+validpgpkeys=('1CEC7A9DF7DA85ABEF843DC0A866D7CCAE087291') # Colin Walters <walters at redhat.com>
+
+prepare() {
+  cd ostree
+
+  # https://github.com/ostreedev/ostree/issues/2685
+  git cherry-pick -n edba4b33be10c052 0a908a180fcce98c
+
+  git submodule init
+  git submodule set-url bsdiff "$srcdir/bsdiff"
+  git submodule set-url libglnx "$srcdir/libglnx"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd ostree
+
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --sbindir=/usr/bin \
+    --libexecdir=/usr/lib \
+    --with-builtin-grub2-mkconfig \
+    --with-ed25519-libsodium \
+    --with-dracut \
+    --with-mkinitcpio \
+    --with-openssl \
+    --enable-experimental-api \
+    --disable-static \
+    --enable-gtk-doc
+
+  # circumvent overlinking
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+check() {
+  cd ostree
+  make check -k || echo "Known to fail: https://github.com/ostreedev/ostree/issues/2313"
+}
+
+package() {
+  depends+=(libarchive.so libavahi-client.so libavahi-common.so
+            libavahi-glib.so libgio-2.0.so libglib-2.0.so libgobject-2.0.so
+            libgpgme.so libsoup-2.4.so libsystemd.so)
+  provides+=(libostree-1.so)
+
+  cd ostree
+  make DESTDIR="$pkgdir" install
+}