[arch-commits] Commit in haskell-regex-tdfa/repos (2 files)

[Felix Yan]

    Date: Thursday, August 18, 2022 @ 12:35:02
  Author: felixonmars
Revision: 1267199

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-regex-tdfa/repos/community-staging-x86_64/
  haskell-regex-tdfa/repos/community-staging-x86_64/PKGBUILD
    (from rev 1267198, haskell-regex-tdfa/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-regex-tdfa/repos/community-staging-x86_64/PKGBUILD (from rev 1267198, haskell-regex-tdfa/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-18 12:35:02 UTC (rev 1267199)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=regex-tdfa
+pkgname=haskell-regex-tdfa
+pkgver=1.3.1.5
+pkgrel=2
+pkgdesc="Pure Haskell Tagged DFA Backend for Text.Regex (regex-base)"
+url="https://wiki.haskell.org/Regular_expressions"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-regex-base')
+makedepends=('ghc' 'uusi' 'haskell-doctest-parallel' 'haskell-utf8-string')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('c16e2aa5e7075763f9ee5b54b0acdd29eb333c722b82e4f9981630d6ef8a3235cd1d5198718e181e7c3fab55dedf5389405f0de26765be3b0778d2e9c87dc073')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    gen-setup
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    # doctest-parallel is currently broken
+    runhaskell Setup test --show-details=direct || echo "Tests failed"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}