[arch-commits] Commit in (3 files)

[Maxime Gauduin]

    Date: Thursday, August 18, 2022 @ 12:48:14
  Author: alucryd
Revision: 1267279

python-rx becomes python-reactivex starting with 4.0.0

Added:
  python-reactivex/
  python-reactivex/trunk/
  python-reactivex/trunk/PKGBUILD

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Added: python-reactivex/trunk/PKGBUILD
===================================================================
--- python-reactivex/trunk/PKGBUILD	                        (rev 0)
+++ python-reactivex/trunk/PKGBUILD	2022-08-18 12:48:14 UTC (rev 1267279)
@@ -0,0 +1,54 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Ilya Elenskiy <elenskiy.ilya at gmail.com>
+# Contributor: Julien Nicoulaud <julien.nicoulaud at gmail.com>
+
+pkgname=python-reactivex
+pkgver=4.0.4
+pkgrel=1
+pkgdesc='Reactive Extensions for Python'
+arch=(any)
+url=http://reactivex.io
+license=(APACHE)
+depends=(
+  python
+  python-typing_extensions
+)
+makedepends=(
+  git
+  python-build
+  python-poetry
+  python-installer
+)
+checkdepends=(
+  python-coverage
+  python-nose
+  python-pytest
+  python-pytest-asyncio
+)
+_tag=7187453c1a829c3f7ceeadae722f2d1d13f6b51e
+source=(git+https://github.com/ReactiveX/RxPY.git#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+  cd RxPY
+  _version=$(git describe --tags | sed 's/^v//')
+  poetry version -q ${_version}
+  echo "__version__ = \"${_version}\"" > reactivex/_version.py
+  echo ${_version}
+}
+
+build() {
+  cd RxPY
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd RxPY
+  python -m pytest
+}
+
+package() {
+  python -m installer --destdir="${pkgdir}" RxPY/dist/*.whl
+}
+
+# vim: ts=2 sw=2 et: