[arch-commits] Commit in haskell-tasty-silver/repos (2 files)

[Felix Yan]

    Date: Thursday, August 18, 2022 @ 12:48:41
  Author: felixonmars
Revision: 1267283

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-tasty-silver/repos/community-staging-x86_64/
  haskell-tasty-silver/repos/community-staging-x86_64/PKGBUILD
    (from rev 1267282, haskell-tasty-silver/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-tasty-silver/repos/community-staging-x86_64/PKGBUILD (from rev 1267282, haskell-tasty-silver/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-18 12:48:41 UTC (rev 1267283)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=tasty-silver
+pkgname=haskell-tasty-silver
+pkgver=3.3.1.1
+pkgrel=19
+pkgdesc="A fancy test runner, including support for golden tests"
+url="https://github.com/phile314/tasty-silver"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-async' 'haskell-optparse-applicative'
+         'haskell-process-extras' 'haskell-regex-tdfa' 'haskell-silently' 'haskell-tagged'
+         'haskell-tasty' 'haskell-temporary')
+makedepends=('ghc' 'haskell-tasty-hunit')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ce4a83904b5e81063b9fc31704b6cc0e0db00f5d9abb2243c48f51441a5d8d5f33dc836da4300290d1b6c8b02600849d4b80aa64a914589cf1be1bba8d9ead28')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}