[arch-commits] Commit in kdenlive/repos (3 files)

[Felix Yan]

    Date: Thursday, August 18, 2022 @ 19:05:41
  Author: felixonmars
Revision: 453413

archrelease: copy trunk to staging-x86_64

Added:
  kdenlive/repos/staging-x86_64/
  kdenlive/repos/staging-x86_64/PKGBUILD
    (from rev 453412, kdenlive/trunk/PKGBUILD)
  kdenlive/repos/staging-x86_64/keys/

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: kdenlive/repos/staging-x86_64/PKGBUILD (from rev 453412, kdenlive/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-08-18 19:05:41 UTC (rev 453413)
@@ -0,0 +1,43 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Zuf <kontakt.zuf at gmail.com>
+# Contributor: Darwin Bautista <djclue917 at gmail.com>
+# Contributor: Gustavo Alvarez <sl1pkn07 at gmail.com>
+
+pkgname=kdenlive
+pkgver=22.08.0
+pkgrel=1
+pkgdesc='A non-linear video editor for Linux using the MLT video framework'
+arch=(x86_64)
+url='https://apps.kde.org/kdenlive/'
+license=(GPL)
+groups=(kde-applications kde-multimedia)
+depends=(qt5-networkauth knewstuff knotifyconfig kfilemetadata purpose mlt breeze-icons frei0r-plugins)
+makedepends=(extra-cmake-modules kdoctools v4l-utils doxygen qt5-tools)
+optdepends=('ffmpeg: for FFmpeg plugin'
+            'dvgrab: for firewire capture'
+            'recordmydesktop: for screen capture'
+            'opencv: for motion tracking'
+            'plasma-desktop: theme configuration'
+            'opentimelineio: timeline export/import'
+            'bigsh0t: VR360 effects'
+            'mediainfo: for technical clip information'
+            'noise-suppression-for-voice: noise suppression effect')
+source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
+sha256sums=('a2639f89fb37759839791a73d6bed4471c131b7f86908937d35d30ada8ac8840'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck at kde.org>
+              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker at kde.org>
+options=(debug)
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_QCH=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}