[arch-commits] Commit in haskell-cassava/repos (2 files)

[Felix Yan]

    Date: Thursday, August 18, 2022 @ 21:52:36
  Author: felixonmars
Revision: 1269236

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-cassava/repos/community-staging-x86_64/
  haskell-cassava/repos/community-staging-x86_64/PKGBUILD
    (from rev 1269235, haskell-cassava/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-cassava/repos/community-staging-x86_64/PKGBUILD (from rev 1269235, haskell-cassava/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-18 21:52:36 UTC (rev 1269236)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=cassava
+pkgname=haskell-cassava
+pkgver=0.5.3.0
+pkgrel=6
+pkgdesc="A CSV parsing and encoding library"
+url="https://github.com/haskell-hvr/cassava"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-hashable' 'haskell-only' 'haskell-scientific'
+         'haskell-text-short' 'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-quickcheck-instances'
+             'haskell-test-framework' 'haskell-test-framework-hunit'
+             'haskell-test-framework-quickcheck2')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('6afae52a2facc013d746a83afa975a2493174e2c5bda0c0ad8cab76c13c46dd86e8d3142e0676c881a35c3c8bf5618a5c1e4b70c3ab153443b949cb84b70bcb4')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-bytestring--LT-0_10_4
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}