[arch-commits] Commit in rbutil/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Maxime Gauduin]

    Date: Friday, August 19, 2022 @ 08:48:41
  Author: alucryd
Revision: 1269700

archrelease: copy trunk to community-x86_64

Added:
  rbutil/repos/community-x86_64/PKGBUILD
    (from rev 1269699, rbutil/trunk/PKGBUILD)
Deleted:
  rbutil/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |  119 +++++++++++++++++++++++++++++--------------------------------
 1 file changed, 58 insertions(+), 61 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-08-19 08:48:32 UTC (rev 1269699)
+++ PKGBUILD	2022-08-19 08:48:41 UTC (rev 1269700)
@@ -1,61 +0,0 @@
-# Maintainer: Maxime Gauduin <alucryd at gmail.com>
-# Contributor: David Runge <dvzrv at archlinux.org>
-# Contributor: said <atvordhosbn at gmail.com>
-# Contributor: clinx <clinx.hacker at googlemail.com>
-
-_name=rockbox
-pkgname=rbutil
-pkgver=1.4.1.r381.g94eb1df58b
-pkgrel=3
-pkgdesc='Rockbox Utility'
-arch=(x86_64)
-url=https://www.rockbox.org/twiki/bin/view/Main/RockboxUtility
-license=(GPL)
-depends=(
-  crypto++
-  qt5-base
-  qt5-multimedia
-  libxkbcommon-x11
-  zlib
-)
-makedepends=(
-  gendesk
-  git
-  libusb
-  qt5-tools
-)
-optdepends=('speex: voice files support')
-# NOTE: commit with latest Qt fixes
-_commit=94eb1df58b
-# NOTE: using git sources, as the build fails during linking with 1.4.1
-source=("git+https://git.${_name}.org/cgit/${_name}.git#commit=${_commit}")
-sha256sums=('SKIP')
-
-prepare() {
-  gendesk -n --pkgname "${pkgname}" --pkgdesc "${pkgdesc}" --name="Rockbox Utility" --exec="RockboxUtility" --categories="Application;Utility;" --comment="Rockbox automated installer"
-}
-
-pkgver() {
-  cd "${_name}"
-  git describe --long --exclude '*archos_retired*' --tags | sed 's/\([^-]*-g\)/r\1/;s/rbutil_//;s/-/./g'
-}
-
-build() {
-  cd "${_name}/${pkgname}/rbutilqt"
-
-  lrelease-qt5 rbutilqt.pro
-  qmake-qt5
-  make
-}
-
-package(){
-  depends+=('libusb-1.0.so')
-  cd "${_name}/${pkgname}/rbutilqt"
-
-  install -dm 755 "${pkgdir}"/usr/{bin,share/{applications,pixmaps}}
-  install -m 755 {,"${pkgdir}"/usr/bin/}RockboxUtility
-  install -m 644 icons/rockbox-256.png "${pkgdir}"/usr/share/pixmaps/rbutil.png
-  install -m 644 {"${srcdir}","${pkgdir}"/usr/share/applications}/rbutil.desktop
-}
-
-# vim: ts=2 sw=2 et:

Copied: rbutil/repos/community-x86_64/PKGBUILD (from rev 1269699, rbutil/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-08-19 08:48:41 UTC (rev 1269700)
@@ -0,0 +1,58 @@
+# Maintainer: Maxime Gauduin <alucryd at gmail.com>
+# Contributor: David Runge <dvzrv at archlinux.org>
+# Contributor: said <atvordhosbn at gmail.com>
+# Contributor: clinx <clinx.hacker at googlemail.com>
+
+pkgname=rbutil
+pkgver=1.5.1
+pkgrel=1
+pkgdesc='Rockbox Utility'
+arch=(x86_64)
+url=https://www.rockbox.org/twiki/bin/view/Main/RockboxUtility
+license=(GPL)
+depends=(
+  gcc-libs
+  glibc
+  libbz2.so
+  libusb-1.0.so
+  qt6-5compat
+  qt6-base
+  qt6-multimedia
+  qt6-svg
+  zlib
+)
+makedepends=(
+  cmake
+  git
+  ninja
+  qt6-tools
+)
+optdepends=('speex: voice files support')
+_tag=f8d54d0d1e8ae891d9da9cf787aa0dd045cc193b
+source=(git+https://git.rockbox.org/cgit/rockbox.git#tag=${_tag})
+b2sums=(SKIP)
+
+prepare() {
+  sed '/add_subdirectory(themeeditor)/d' -i rockbox/utils/CMakeLists.txt
+}
+
+pkgver() {
+  cd rockbox
+  git describe --tags | sed 's/rbutil_//'
+}
+
+build() {
+  cmake -S rockbox/utils -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -Wno-dev
+  cmake --build build
+}
+
+package(){
+  install -Dm 755 build/rbutilqt/RockboxUtility -t "${pkgdir}"/usr/bin/
+  install -Dm 644 rockbox/utils/rbutilqt/RockboxUtility.desktop -t "${pkgdir}"/usr/share/applications/
+  install -Dm 644 rockbox/docs/logo/rockbox-clef.svg -t "${pkgdir}"/usr/share/pixmaps/
+}
+
+# vim: ts=2 sw=2 et: