[arch-commits] Commit in broot/repos (2 files)

[Felix Yan]

    Date: Friday, August 19, 2022 @ 08:52:20
  Author: felixonmars
Revision: 1269721

archrelease: copy trunk to community-staging-x86_64

Added:
  broot/repos/community-staging-x86_64/
  broot/repos/community-staging-x86_64/PKGBUILD
    (from rev 1269720, broot/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: broot/repos/community-staging-x86_64/PKGBUILD (from rev 1269720, broot/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-19 08:52:20 UTC (rev 1269721)
@@ -0,0 +1,47 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at archlinux.org>
+# Maintainer: Orhun Parmaksız <orhun at archlinux.org>
+# Contributor: Adam Fontenot <adam.m.fontenot at gmail.com>
+# Contributor: Daniel M. Capella <polyzen at archlinux.org>
+
+pkgname=broot
+pkgver=1.14.2
+pkgrel=2
+pkgdesc='Fuzzy Search + tree + cd'
+arch=('x86_64')
+url=https://github.com/Canop/broot
+license=('MIT')
+depends=('gcc-libs' 'zlib' 'libgit2')
+makedepends=('cargo')
+options=('!lto')
+source=("https://github.com/Canop/broot/archive/v$pkgver/$pkgname-v$pkgver.tar.gz")
+sha256sums=('992e3b5c2b73a25366bf67ccc8d99a51be9c07c75ec6ea413883dd8a8857c2e4')
+
+prepare() {
+  cd $pkgname-$pkgver
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd $pkgname-$pkgver
+  cargo build --release --frozen
+}
+
+check() {
+  cd $pkgname-$pkgver
+  cargo test --frozen
+}
+
+package() {
+  cd $pkgname-$pkgver
+  install -Dt "$pkgdir"/usr/bin target/release/$pkgname
+  sed -i "s/#version/$pkgver/" man/page
+  # Theoretically we could get the date from the CHANGELOG.md but it seems that the
+  # CHANGELOG.md entry for the current version isn't actually in the current release.
+  # changelog_date=$(sed -n "s/.*v$pkgver - \(.*\)$/\1/p" CHANGELOG.md)
+  sed -i "s/#date//" man/page
+  install -Dm644 man/page "$pkgdir/usr/share/man/man1/$pkgname.1"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -Dm644 resources/icons/vscode/vscode.ttf "$pkgdir/usr/share/fonts/TTF/vscode.ttf"
+}
+
+# vim:set ts=2 sw=2 et: