[arch-commits] Commit in ropper/trunk (PKGBUILD)

[Levente Polyak]

    Date: Friday, August 19, 2022 @ 17:02:17
  Author: anthraxx
Revision: 1270963

upgpkg: ropper 1.13.8-1: unified python-ropper and ropper

Modified:
  ropper/trunk/PKGBUILD

----------+
 PKGBUILD |   36 +++++++++++++++---------------------
 1 file changed, 15 insertions(+), 21 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-08-19 16:57:52 UTC (rev 1270962)
+++ PKGBUILD	2022-08-19 17:02:17 UTC (rev 1270963)
@@ -1,44 +1,38 @@
 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
 
-pkgbase=ropper
-pkgname=('ropper' 'python-ropper')
+pkgname=ropper
 _pkgname=Ropper
-pkgver=1.13.7
+pkgver=1.13.8
 pkgrel=1
 pkgdesc='Show information about binary files and find gadgets to build rop chains for different architectures'
 url='https://github.com/sashs/Ropper'
 arch=('any')
 license=('GPL2')
-makedepends=('python-setuptools' 'python-capstone' 'python-filebytes')
+depends=('python' 'python-capstone' 'python-filebytes')
+makedepends=('python-build' 'python-installer' 'python-wheel' 'python-setuptools')
+checkdepends=('python-pytest')
+optdepends=('python-keystone: assemble command support')
+conflicts=('python-ropper')
+replaces=('python-ropper')
+provides=('python-ropper')
 source=(https://github.com/sashs/${_pkgname}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
-sha512sums=('1d93c4d58454bbd5cfb6a4a7a69f571294613e10e77cae6a65eaf7b9a5c977a3b82c888bd414d1b3e6a1082ba7cd9f2121253bf849dff2a40cdb34acb1371acf')
+sha512sums=('eae2279e1c6bc91af76e8e5d37b7d57c5d2e518d027e293dbd52c6c27dcd8826e73673c55fe581cdefda272b657c8eff2b5eb4fdc4996fec1548709b8371b5d4')
+b2sums=('8601bcd2287763aa208b227c437362b9799ec1775104b659213e69a77f118bce567e95a0b83a4f0556439a82ee853ebc9aabaa4098b2a700572d1b661213eb25')
 
 build() {
   cd ${_pkgname}-${pkgver}
-  python setup.py build
+  python -m build --wheel --no-isolation
 }
 
 check() {
   cd ${_pkgname}-${pkgver}
-  python test.py
+  py.test
 }
 
-package_ropper() {
-  depends=('python' "python-ropper>=${pkgver}")
-  optdepends=('python-keystone: assemble command support')
+package() {
   cd ${_pkgname}-${pkgver}
-  python setup.py install -O1 --root="${pkgdir}" --skip-build
-  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
-  rm -r "${pkgdir}/usr/lib"
-}
-
-package_python-ropper() {
-  depends=('python-capstone' 'python-filebytes')
-  optdepends=('python-keystone: assemble command support')
-  cd ${_pkgname}-${pkgver}
-  python setup.py install -O1 --root="${pkgdir}" --skip-build
+  python -m installer --destdir="$pkgdir" dist/*.whl
   install -Dm 644 README.md sample.py -t "${pkgdir}/usr/share/doc/${pkgname}"
-  rm -r "${pkgdir}/usr/bin"
 }
 
 # vim: ts=2 sw=2 et: