[arch-commits] Commit in radare2/repos (2 files)
Levente Polyak
anthraxx at gemini.archlinux.org
Fri Aug 19 19:10:01 UTC 2022
Date: Friday, August 19, 2022 @ 19:10:01
Author: anthraxx
Revision: 1270982
archrelease: copy trunk to community-staging-x86_64
Added:
radare2/repos/community-staging-x86_64/
radare2/repos/community-staging-x86_64/PKGBUILD
(from rev 1270981, radare2/trunk/PKGBUILD)
----------+
PKGBUILD | 47 +++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 47 insertions(+)
Copied: radare2/repos/community-staging-x86_64/PKGBUILD (from rev 1270981, radare2/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-08-19 19:10:01 UTC (rev 1270982)
@@ -0,0 +1,47 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Guillermo Ramos <0xwille at gmail dot com>
+
+pkgname=radare2
+pkgver=5.7.6
+pkgrel=1
+pkgdesc='Open-source tools to disasm, debug, analyze and manipulate binary files'
+url='https://radare.org'
+arch=('x86_64')
+license=('GPL3' 'LGPL3')
+depends=('sh' 'capstone' 'libcapstone.so' 'openssl' 'libzip' 'zlib'
+ 'lz4' 'xxhash' 'libxxhash.so' 'file' 'libuv' 'tree-sitter'
+ 'libtree-sitter.so' 'libzip.so' 'libmagic.so')
+makedepends=('meson')
+optdepends=('r2ghidra: ghidra decompiler plugin')
+options=('!emptydirs')
+source=(https://github.com/radare/radare2/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('04717ddb4bef9ed415c22aa25a0bf626f05c5d32133ac46d5e8a30ebe83e7b782a2b1835233f17f16315a99a39b33dd4e67c34798eb8ae9fbc6db51ca1051e94')
+b2sums=('e0bd54fcf4a56b34ec6f3b87ab6a20a8be23514e48842d66d7a30f517fa9ba871bd1e740604840fb16a3ae1329221ee67645774ac7df9f8f8d00dc3548dc7830')
+
+build() {
+ cd ${pkgname}-${pkgver}
+ touch libr/config.mk
+ arch-meson build \
+ -D use_sys_capstone=true \
+ -D use_capstone_version=v4 \
+ -D use_sys_magic=true \
+ -D use_sys_zip=true \
+ -D use_sys_zlib=true \
+ -D use_sys_lz4=true \
+ -D use_sys_xxhash=true \
+ -D use_sys_openssl=true \
+ -D use_libuv=true \
+ -D use_webui=true \
+ -D want_threads=false
+
+ ninja -C build
+}
+
+package() {
+ cd ${pkgname}-${pkgver}
+ DESTDIR="${pkgdir}" ninja -C build install
+ cp -r doc/* "${pkgdir}/usr/share/doc/radare2"
+ ln -s /usr/share/man/man1/radare2.1.gz "${pkgdir}/usr/share/man/man1/r2.1.gz"
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list