[arch-commits] Commit in zfp/repos (2 files)
Felix Yan
felixonmars at gemini.archlinux.org
Fri Aug 19 19:18:55 UTC 2022
Date: Friday, August 19, 2022 @ 19:18:55
Author: felixonmars
Revision: 1270984
archrelease: copy trunk to community-testing-x86_64
Added:
zfp/repos/community-testing-x86_64/
zfp/repos/community-testing-x86_64/PKGBUILD
(from rev 1270983, zfp/trunk/PKGBUILD)
----------+
PKGBUILD | 41 +++++++++++++++++++++++++++++++++++++++++
1 file changed, 41 insertions(+)
Copied: zfp/repos/community-testing-x86_64/PKGBUILD (from rev 1270983, zfp/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2022-08-19 19:18:55 UTC (rev 1270984)
@@ -0,0 +1,41 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=zfp
+pkgver=1.0.0
+pkgrel=1
+pkgdesc="Compressed numerical arrays that support high-speed random access"
+arch=(x86_64)
+url="https://computing.llnl.gov/projects/floating-point-compression"
+license=(BSD)
+depends=(glibc gcc-libs)
+makedepends=(cmake gcc-fortran cython python python-numpy)
+source=(https://github.com/LLNL/zfp/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz
+ zfp-fix-libm-check.patch::https://github.com/LLNL/zfp/commit/6d7d2424ed082eb41d696036b26831636650a614.patch)
+sha256sums=('fe13b03141ee9b571692aed42ff76cf37c9dcda40f9a43a808870dca3558a57c'
+ 'fb90be8fd65448a209ea18e042e91d9207ebef63320da5cda9a2902309154e48')
+
+prepare() {
+ # https://github.com/LLNL/zfp/issues/169
+ patch -d $pkgname-$pkgver -Np1 < zfp-fix-libm-check.patch
+}
+
+build() {
+ cmake -B build -S ${pkgname}-${pkgver} \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_SKIP_RPATH=ON \
+ -DBUILD_CFP=ON \
+ -DBUILD_ZFPY=ON \
+ -DBUILD_ZFORP=ON
+ make -C build
+}
+
+check() {
+ cd build
+ LD_LIBRARY_PATH="$(pwd)"/lib/ ctest -v --output-on-failure
+}
+
+package() {
+ make -C build DESTDIR="${pkgdir}" install
+ install -D build/bin/zfp -t "${pkgdir}"/usr/bin
+ install -Dm644 ${pkgname}-${pkgver}/LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
More information about the arch-commits
mailing list