[arch-commits] Commit in (4 files)

[Levente Polyak]

    Date: Saturday, August 20, 2022 @ 00:33:10
  Author: anthraxx
Revision: 1271010

addpkg: python-pyvex 9.2.14-1

Added:
  python-pyvex/
  python-pyvex/repos/
  python-pyvex/trunk/
  python-pyvex/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: python-pyvex/trunk/PKGBUILD
===================================================================
--- python-pyvex/trunk/PKGBUILD	                        (rev 0)
+++ python-pyvex/trunk/PKGBUILD	2022-08-20 00:33:10 UTC (rev 1271010)
@@ -0,0 +1,49 @@
+# Maintainer: ArchStrike <team at archstrike.org>
+
+_pyname=pyvex
+pkgname=python-${_pyname}
+pkgver=9.2.14
+pkgrel=1
+pkgdesc="Python bindings for Valgrind's VEX IR"
+url='https://github.com/angr/pyvex'
+license=('BSD')
+arch=('x86_64')
+depends=('python' 'python-archinfo' 'python-bitstring' 'python-cffi' 'python-setuptools')
+makedepends=('git' 'python-build' 'python-installer' 'python-wheel')
+checkdepends=('python-pytest')
+source=("git+${url}.git#commit=v${pkgver}"
+        git+https://github.com/angr/vex.git)
+sha512sums=('SKIP'
+            'SKIP')
+
+prepare() {
+  cd ${_pyname}
+  git submodule init
+  git config submodule."vex".url "${srcdir}/vex"
+  git submodule update --recursive
+
+  sed 's/FLAGS=/FLAGS+=/g' -i pyvex_c/Makefile
+  sed 's/-shared/$(LDFLAGS) -shared/' -i "${srcdir}"/vex/Makefile-gcc
+}
+
+build() {
+  cd ${_pyname}
+  export EXTRA_CFLAGS="${CFLAGS} ${CPPFLAGS}"
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd ${_pyname}
+  # TODO: enable all tests once angr is packaged
+  rm tests/test_spotter.py
+  PYTHONPATH=build/lib pytest
+}
+
+package() {
+  cd ${_pyname}
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: