[arch-commits] Commit in python-pygit2/repos (2 files)

[Caleb Maclennan]

    Date: Saturday, August 20, 2022 @ 10:38:36
  Author: alerque
Revision: 1271045

archrelease: copy trunk to community-staging-x86_64

Added:
  python-pygit2/repos/community-staging-x86_64/
  python-pygit2/repos/community-staging-x86_64/PKGBUILD
    (from rev 1271044, python-pygit2/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: python-pygit2/repos/community-staging-x86_64/PKGBUILD (from rev 1271044, python-pygit2/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-20 10:38:36 UTC (rev 1271045)
@@ -0,0 +1,39 @@
+# Maintainer: Lukas Fleischer <lfleischer at archlinux.org>
+# Maintainer: Jaroslav Lichtblau <svetlemodry at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Daniel Micay <danielmicay at gmail.com>
+
+pkgname=python-pygit2
+pkgver=1.10.0
+pkgrel=1
+pkgdesc='Python bindings for libgit2'
+arch=('x86_64')
+url="https://github.com/libgit2/pygit2"
+license=('GPL2')
+depends=('libgit2' 'libgit2.so' 'python-cffi' 'python-six' 'python-cached-property')
+makedepends=('cython' 'python-build' 'python-cffi' 'python-installer' 'python-setuptools' 'git' 'python-six' 'python-wheel')
+checkdepends=('python-pytest-runner')
+source=("$url/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('f86f76812a1eed69b4b36757ddf77a1e455d8dc508ed26550b4e4be46e5e79af')
+
+prepare() {
+	cd "pygit2-$pkgver"
+	# Disable tests that do stuff online
+	sed -i -e '/has_network/s/True/False/' test/utils.py
+}
+
+build() {
+	cd "pygit2-$pkgver"
+	python -m build -wn
+}
+
+check() {
+	cd "pygit2-$pkgver"
+	local _pyver=cpython-$(python -c 'import sys; print("".join(map(str, sys.version_info[:2])))')
+	PYTHONPATH="$PWD/build/lib.linux-$CARCH-$_pyver" pytest
+}
+
+package() {
+	cd "pygit2-$pkgver"
+	LANG=en_US.UTF8 python -m installer -d "${pkgdir}" dist/*.whl
+}