[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, August 20, 2022 @ 12:57:15
  Author: felixonmars
Revision: 1271056

addpkg: haskell-linear 1.21.10-1

Added:
  haskell-linear/
  haskell-linear/repos/
  haskell-linear/trunk/
  haskell-linear/trunk/PKGBUILD

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Added: haskell-linear/trunk/PKGBUILD
===================================================================
--- haskell-linear/trunk/PKGBUILD	                        (rev 0)
+++ haskell-linear/trunk/PKGBUILD	2022-08-20 12:57:15 UTC (rev 1271056)
@@ -0,0 +1,56 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=linear
+pkgname=haskell-linear
+pkgver=1.21.10
+pkgrel=1
+pkgdesc="Linear Algebra"
+url="http://github.com/ekmett/linear/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-adjunctions' 'haskell-base-orphans' 'haskell-bytes' 'haskell-cereal'
+         'haskell-distributive' 'haskell-hashable' 'haskell-indexed-traversable' 'haskell-lens'
+         'haskell-random' 'haskell-reflection' 'haskell-semigroupoids' 'haskell-tagged'
+         'haskell-transformers-compat' 'haskell-unordered-containers' 'haskell-vector'
+         'haskell-void')
+makedepends=('ghc' 'uusi' 'haskell-hunit' 'haskell-simple-reflect' 'haskell-test-framework'
+             'haskell-test-framework-hunit')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('b90733227c9d4047e087a0083785e8293dc623169161c6dab12ece1ac90d7ab4')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  uusi -d semigroups $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=haskell-linear --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie' \
+    -f-herbie -ftemplate-haskell
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}