[arch-commits] Commit in sdl2/repos (3 files)

[Sven-Hendrik Haase]

    Date: Saturday, August 20, 2022 @ 17:14:40
  Author: svenstaro
Revision: 454082

archrelease: copy trunk to testing-x86_64

Added:
  sdl2/repos/testing-x86_64/
  sdl2/repos/testing-x86_64/PKGBUILD
    (from rev 454081, sdl2/trunk/PKGBUILD)
  sdl2/repos/testing-x86_64/keys/

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: sdl2/repos/testing-x86_64/PKGBUILD (from rev 454081, sdl2/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-08-20 17:14:40 UTC (rev 454082)
@@ -0,0 +1,41 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at archlinux.org>
+pkgname=sdl2
+pkgver=2.24.0
+pkgrel=1
+pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 2)"
+arch=('x86_64')
+url="https://www.libsdl.org"
+license=('MIT')
+depends=('glibc' 'libxext' 'libxrender' 'libx11' 'libgl' 'libxcursor' 'hidapi' 'libusb')
+makedepends=('alsa-lib' 'mesa' 'libpulse' 'libxrandr' 'libxinerama' 'wayland' 'libxkbcommon'
+             'wayland-protocols' 'ibus' 'fcitx5' 'libxss' 'cmake' 'jack' 'ninja' 'pipewire'
+             'libdecor')
+optdepends=('alsa-lib: ALSA audio driver'
+            'libpulse: PulseAudio audio driver'
+            'jack: JACK audio driver'
+            'pipewire: PipeWire audio driver'
+            'libdecor: Wayland client decorations')
+source=("https://github.com/libsdl-org/SDL/releases/download/release-${pkgver}/SDL2-${pkgver}.tar.gz"{,.sig})
+sha512sums=('5735bfc7b22f1780f80cc89f62a14ca809fe1280298d172f92dde74400db1f5378f8d3eae8834e886d3ca4f5ae6f1074d66c5c956613cf9e0cce961738514212'
+            'SKIP')
+validpgpkeys=('1528635D8053A57F77D1E08630A59377A7763BE6') # Sam Lantinga
+
+build() {
+  CFLAGS+=" -ffat-lto-objects"
+  cmake -S SDL2-${pkgver} -B build -G Ninja \
+    -D CMAKE_INSTALL_PREFIX=/usr \
+    -D SDL_STATIC=OFF \
+    -D SDL_RPATH=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --install build
+
+  # For some reason, this isn't named correctly and we have to fix it to reflect the actual staticlib name.
+  sed -i "s/libSDL2\.a/libSDL2main.a/g" "$pkgdir"/usr/lib/cmake/SDL2/SDL2Targets-noconfig.cmake
+
+  install -Dm644 SDL2-${pkgver}/LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et: