[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, August 20, 2022 @ 18:52:45
  Author: felixonmars
Revision: 1271112

addpkg: haskell-hoauth2 2.0.0-1

Added:
  haskell-hoauth2/
  haskell-hoauth2/repos/
  haskell-hoauth2/trunk/
  haskell-hoauth2/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: haskell-hoauth2/trunk/PKGBUILD
===================================================================
--- haskell-hoauth2/trunk/PKGBUILD	                        (rev 0)
+++ haskell-hoauth2/trunk/PKGBUILD	2022-08-20 18:52:45 UTC (rev 1271112)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hoauth2
+pkgname=haskell-hoauth2
+pkgver=2.0.0
+pkgrel=1
+pkgdesc="Haskell OAuth2 authentication client"
+url="https://github.com/freizl/hoauth2"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-hashable' 'haskell-http-conduit'
+         'haskell-http-types' 'haskell-microlens' 'haskell-unordered-containers'
+         'haskell-uri-bytestring' 'haskell-uri-bytestring-aeson')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('8b8f8f9fe4e0a9ae4d953079f6c59d56b522648962f894c1354ff248dd8aa280')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie' 
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}