[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, August 20, 2022 @ 19:21:42
  Author: felixonmars
Revision: 1271124

addpkg: haskell-irc-core 2.11-1

Added:
  haskell-irc-core/
  haskell-irc-core/repos/
  haskell-irc-core/trunk/
  haskell-irc-core/trunk/PKGBUILD

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Added: haskell-irc-core/trunk/PKGBUILD
===================================================================
--- haskell-irc-core/trunk/PKGBUILD	                        (rev 0)
+++ haskell-irc-core/trunk/PKGBUILD	2022-08-20 19:21:42 UTC (rev 1271124)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=irc-core
+pkgname=haskell-irc-core
+pkgver=2.11
+pkgrel=1
+pkgdesc="IRC core library for glirc"
+url="https://github.com/glguy/irc-core"
+license=("ISC")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-base64-bytestring' 'haskell-hashable'
+         'haskell-primitive' 'haskell-vector')
+makedepends=('ghc' 'haskell-hunit')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('ccd9f7e3975a2f7079b45d571f6c3607648ad2939d6ac14a69d8fa09c672538e')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie' 
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}