[arch-commits] Commit in haskell-doctest-parallel/repos (2 files)

[Felix Yan]

    Date: Saturday, August 20, 2022 @ 22:08:04
  Author: felixonmars
Revision: 1271431

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-doctest-parallel/repos/community-staging-x86_64/
  haskell-doctest-parallel/repos/community-staging-x86_64/PKGBUILD
    (from rev 1271430, haskell-doctest-parallel/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: haskell-doctest-parallel/repos/community-staging-x86_64/PKGBUILD (from rev 1271430, haskell-doctest-parallel/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-20 22:08:04 UTC (rev 1271431)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=doctest-parallel
+pkgname=haskell-doctest-parallel
+pkgver=0.2.3
+pkgrel=9
+pkgdesc="Test interactive Haskell examples"
+url="https://github.com/martijnbastiaan/doctest-parallel#readme"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-glob' 'haskell-base-compat' 'haskell-code-page' 'haskell-extra'
+         'haskell-ghc' 'haskell-ghc-paths' 'haskell-random' 'haskell-syb'
+         'haskell-unordered-containers')
+makedepends=('ghc' 'expac' 'haskell-hunit' 'haskell-quickcheck' 'haskell-hspec' 'haskell-hspec-core'
+             'haskell-hspec-discover' 'haskell-mockery' 'haskell-setenv' 'haskell-silently'
+             'haskell-stringbuilder')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('3b09013f9c8af7e8404a29c4aeb0c6c34e25690770dd3b47608f613d414a616a')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  # == An ugly hack to generate .ghc.environment without cabal-install ==
+  # doctest-parallel relies on this cabal-install feature to configure GHCi.
+  # https://github.com/martijnbastiaan/doctest-parallel/issues/22
+  _ghc_env_filename=.ghc.environment.$CARCH-linux-$(expac %v ghc | cut -d - -f 1)
+  echo -e "package-db dist/package.conf.inplace" > $_ghc_env_filename
+  ls dist/package.conf.inplace/*.conf | sed 's|.*/\(.*\).conf$|package-id \1|' >> $_ghc_env_filename
+  ls /usr/lib/ghc-9.0.2/package.conf.d/*.conf | sed 's|.*/\(.*\).conf$|package-id \1|' >> $_ghc_env_filename
+
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}