[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, August 21, 2022 @ 07:24:27
  Author: felixonmars
Revision: 1271640

addpkg: haskell-oeis 0.3.10-1

Added:
  haskell-oeis/
  haskell-oeis/repos/
  haskell-oeis/trunk/
  haskell-oeis/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: haskell-oeis/trunk/PKGBUILD
===================================================================
--- haskell-oeis/trunk/PKGBUILD	                        (rev 0)
+++ haskell-oeis/trunk/PKGBUILD	2022-08-21 07:24:27 UTC (rev 1271640)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=oeis
+pkgname=haskell-oeis
+pkgver=0.3.10
+pkgrel=1
+pkgdesc="Interface to the Online Encyclopedia of Integer Sequences (OEIS)"
+url="https://github.com/niteria/oeis.git"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-http' 'haskell-network' 'haskell-network-uri')
+makedepends=('ghc' 'uusi' 'haskell-hunit' 'haskell-test-framework' 'haskell-test-framework-hunit')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('bbfa724d9f69f14bcc95a5ecbd94a3e0ec1b072b69a5413c70174d2406884529')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  uusi -u HTTP $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie' \
+    -fnetwork-uri
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}