[arch-commits] Commit in haskell-jose/repos (2 files)

[Felix Yan]

    Date: Sunday, August 21, 2022 @ 17:58:49
  Author: felixonmars
Revision: 1273229

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-jose/repos/community-staging-x86_64/
  haskell-jose/repos/community-staging-x86_64/PKGBUILD
    (from rev 1273228, haskell-jose/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-jose/repos/community-staging-x86_64/PKGBUILD (from rev 1273228, haskell-jose/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-21 17:58:49 UTC (rev 1273229)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=jose
+pkgname=haskell-jose
+pkgver=0.8.5.1
+pkgrel=11
+pkgdesc="Javascript Object Signing and Encryption (JOSE) and JSON Web Token (JWT) library"
+url="https://github.com/frasertweedale/hs-jose"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck' 'haskell-aeson' 'haskell-attoparsec'
+         'haskell-base64-bytestring' 'haskell-concise' 'haskell-cryptonite' 'haskell-lens'
+         'haskell-memory' 'haskell-monad-time' 'haskell-network-uri' 'haskell-quickcheck-instances'
+         'haskell-safe' 'haskell-unordered-containers' 'haskell-vector' 'haskell-x509' )
+makedepends=('ghc' 'haskell-hspec' 'haskell-pem' 'haskell-tasty' 'haskell-tasty-hspec'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ecba9c8eb03f9dfff34dcab4720ec1c0285c24dccb5d220e0e76c1e57c758aaa6af2b3e56dbac0057185a9f23407386ea6b298bbb03c04afb5aa302db58b5741')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}