[arch-commits] Commit in cargo-crev/repos (2 files)

[Kpcyrd]

    Date: Monday, August 22, 2022 @ 01:11:20
  Author: kpcyrd
Revision: 1274222

archrelease: copy trunk to community-staging-x86_64

Added:
  cargo-crev/repos/community-staging-x86_64/
  cargo-crev/repos/community-staging-x86_64/PKGBUILD
    (from rev 1274221, cargo-crev/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: cargo-crev/repos/community-staging-x86_64/PKGBUILD (from rev 1274221, cargo-crev/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-22 01:11:20 UTC (rev 1274222)
@@ -0,0 +1,41 @@
+# Maintainer: kpcyrd <git at rxv.cc>
+# Maintainer: Orhun Parmaksız <orhun at archlinux.org>
+
+pkgname=cargo-crev
+pkgver=0.23.3
+pkgrel=2
+pkgdesc="Scalable, social, Code REView and recommendation system that we desperately need"
+url="https://github.com/crev-dev/cargo-crev"
+depends=('openssl' 'libcurl.so' 'libgit2.so')
+makedepends=('cargo' 'clang')
+arch=('x86_64')
+license=('MPL' 'Apache' 'MIT')
+options=('!lto')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/crev-dev/cargo-crev/archive/v${pkgver}.tar.gz")
+sha512sums=('4bdce82367e1233eb4db4ecfad1c208c2aa4bf55617156ef998fd78b986a496e1e6f6eec17c319479195f043df960b105f642a15b7cbcb9f69036c5355f3fc34')
+b2sums=('256a34e3e9759c6264623e206c472ec64491b784febd0a304d6e68247e3d8cfb544364d4952f580395914bd2bbaf01fc2c5dfe1c4268a314f7817b862416d6b2')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  LIBSSH2_SYS_USE_PKG_CONFIG=1 cargo build --frozen --release --no-default-features
+}
+
+check() {
+  cd "${pkgname}-${pkgver}"
+  LIBSSH2_SYS_USE_PKG_CONFIG=1 cargo test --frozen --no-default-features
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  install -Dm755 "target/release/${pkgname}" -t "${pkgdir}/usr/bin"
+
+  install -Dm644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm644 LICENSE-MIT -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim:set ts=2 sw=2 et: