[arch-commits] Commit in pandoc/repos (2 files)

Felix Yan felixonmars at gemini.archlinux.org
Mon Aug 22 18:44:59 UTC 2022


    Date: Monday, August 22, 2022 @ 18:44:59
  Author: felixonmars
Revision: 1274833

archrelease: copy trunk to community-staging-x86_64

Added:
  pandoc/repos/community-staging-x86_64/
  pandoc/repos/community-staging-x86_64/PKGBUILD
    (from rev 1274832, pandoc/trunk/PKGBUILD)

----------+
 PKGBUILD |   69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

Copied: pandoc/repos/community-staging-x86_64/PKGBUILD (from rev 1274832, pandoc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-22 18:44:59 UTC (rev 1274833)
@@ -0,0 +1,69 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=pandoc
+pkgver=2.18
+pkgrel=30
+pkgdesc='Conversion between markup formats'
+url='https://pandoc.org'
+license=('GPL')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-glob' 'haskell-juicypixels' 'haskell-sha' 'haskell-aeson'
+         'haskell-aeson-pretty' 'haskell-attoparsec' 'haskell-base64-bytestring'
+         'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-case-insensitive' 'haskell-citeproc'
+         'haskell-commonmark' 'haskell-commonmark-extensions' 'haskell-commonmark-pandoc'
+         'haskell-connection' 'haskell-data-default' 'haskell-doclayout' 'haskell-doctemplates'
+         'haskell-emojis' 'haskell-file-embed' 'haskell-haddock-library' 'haskell-hslua'
+         'haskell-hslua-module-doclayout' 'haskell-hslua-module-path' 'haskell-hslua-module-system'
+         'haskell-hslua-module-text' 'haskell-hslua-module-version' 'haskell-http-client'
+         'haskell-http-client-tls' 'haskell-http-types' 'haskell-ipynb' 'haskell-jira-wiki-markup'
+         'haskell-lpeg' 'haskell-network' 'haskell-network-uri' 'haskell-pandoc-lua-marshal'
+         'haskell-pandoc-types' 'haskell-pretty-show' 'haskell-random' 'haskell-safe'
+         'haskell-scientific' 'haskell-skylighting' 'haskell-skylighting-core' 'haskell-split'
+         'haskell-syb' 'haskell-tagsoup' 'haskell-temporary' 'haskell-texmath'
+         'haskell-text-conversions' 'haskell-unicode-collation' 'haskell-unicode-transforms'
+         'haskell-xml' 'haskell-xml-conduit' 'haskell-xml-types' 'haskell-yaml'
+         'haskell-zip-archive' 'haskell-zlib')
+optdepends=('pandoc-crossref: for numbering figures, equations, tables and cross-references to them with pandoc-crossref filter'
+            'texlive-core: for pdf output')
+conflicts=('haskell-pandoc')
+replaces=('haskell-pandoc')
+makedepends=('ghc' 'haskell-diff' 'haskell-tasty' 'haskell-tasty-golden' 'haskell-tasty-hunit'
+             'haskell-tasty-lua' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('0e8210a37dda6818b23b9fac25b73b240d67f8e03c41d1f3a776dcf95d7fdf48354a25c08ad64eea069003f4ab7a3167ee9c3e80d4f6684ad6ec33d8c477d212')
+
+prepare() {
+    cd $pkgname-$pkgver
+    # TODO: find a better solution
+    sed -i "s|let env' = dynlibEnv ++ |let env' = dynlibEnv ++ [(\"LD_LIBRARY_PATH\", \"$PWD/dist/build\")] ++ |" test/Tests/Command.hs
+}
+
+build() {
+    cd $pkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/$pkgname" --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-trypandoc -f-embed_data_files -f-static
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup test || echo "Tests failed"
+}
+
+package() {
+    cd $pkgname-$pkgver
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm "${pkgdir}/usr/share/doc/${pkgname}/COPYING.md"
+    install -Dm644 man/pandoc.1 -t "${pkgdir}"/usr/share/man/man1/
+}



More information about the arch-commits mailing list