[arch-commits] Commit in zbar/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Felix Yan]

    Date: Tuesday, August 23, 2022 @ 19:13:52
  Author: felixonmars
Revision: 454451

archrelease: copy trunk to testing-x86_64

Added:
  zbar/repos/testing-x86_64/
  zbar/repos/testing-x86_64/PKGBUILD
    (from rev 454450, zbar/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: zbar/repos/testing-x86_64/PKGBUILD (from rev 454450, zbar/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-08-23 19:13:52 UTC (rev 454451)
@@ -0,0 +1,41 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Marti Raudsepp <marti at juffo.org>
+# Contributor: Radu Andries <admiral0 at tuxfamily.org>
+# Contributor: Andy Weidenbaum <archbaum at gmail.com>
+
+pkgname=zbar
+pkgver=0.23.90
+pkgrel=1
+pkgdesc="Application and library for reading bar codes from various sources"
+arch=('x86_64')
+url="https://github.com/mchehab/zbar"
+license=('LGPL')
+depends=('dbus' 'imagemagick' 'libsm' 'libxv' 'v4l-utils')
+makedepends=('gtk3' 'qt5-x11extras' 'python' 'xmlto' 'docbook-xsl' 'gobject-introspection')
+optdepends=('gtk3: for zbar-gtk'
+            'qt5-x11extras: for zbar-qt'
+            'python: for zbar python bindings')
+conflicts=('zbar-gtk' 'zbar-qt' 'python-zbar')
+provides=('zbar-gtk' 'zbar-qt' 'python-zbar')
+replaces=('zbar-gtk' 'zbar-qt' 'python-zbar')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/mchehab/zbar/archive/$pkgver.tar.gz")
+sha512sums=('d73d71873bec68ee021997512a9edbd223f5f5fe43c66c4dd3502224ba6009be2e5e1714766cb8e1056244673e87e0939ed0319116f61d7371b5ab79fb5e04eb')
+
+prepare() {
+  cd zbar-$pkgver
+  autoreconf -vfi
+}
+
+build() {
+  cd zbar-$pkgver
+  ./configure --prefix=/usr --with-qt --with-gtk=gtk3 --with-dbusconfdir=/usr/share CFLAGS="$CFLAGS -DNDEBUG"
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd zbar-$pkgver
+  make DESTDIR="$pkgdir" install
+}
+
+# vim:set ts=2 sw=2 et: