[arch-commits] Commit in haskell-tree-diff/repos (2 files)

[Felix Yan]

    Date: Wednesday, August 24, 2022 @ 05:46:13
  Author: felixonmars
Revision: 1275989

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-tree-diff/repos/community-staging-x86_64/
  haskell-tree-diff/repos/community-staging-x86_64/PKGBUILD
    (from rev 1275988, haskell-tree-diff/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: haskell-tree-diff/repos/community-staging-x86_64/PKGBUILD (from rev 1275988, haskell-tree-diff/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-24 05:46:13 UTC (rev 1275989)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=tree-diff
+pkgname=haskell-tree-diff
+pkgver=0.2.2
+pkgrel=1
+pkgdesc="Diffing of (expression) trees"
+url="https://github.com/phadej/tree-diff"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-wl-pprint' 'haskell-ansi-terminal'
+         'haskell-base-compat' 'haskell-hashable' 'haskell-parsers' 'haskell-primitive'
+         'haskell-quickcheck' 'haskell-scientific' 'haskell-semialign' 'haskell-strict'
+         'haskell-tagged' 'haskell-these' 'haskell-unordered-containers' 'haskell-uuid-types'
+         'haskell-vector')
+makedepends=('ghc' 'uusi' 'haskell-trifecta' 'haskell-tasty' 'haskell-tasty-golden'
+             'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('ee93932dc26924c74dd6a43bad75cde5b300f5e10ec714c22ee262161c750ad0bbc43be2c7bd0f9ff1e27455df0720bf9cc8257ff71fd612413204f3522fb196')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    gen-setup
+    uusi -d bytestring-builder $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}