[arch-commits] Commit in python-pythonfinder/repos/community-any (PKGBUILD PKGBUILD)

[David Runge]

    Date: Wednesday, August 24, 2022 @ 14:24:23
  Author: dvzrv
Revision: 1276408

archrelease: copy trunk to community-any

Added:
  python-pythonfinder/repos/community-any/PKGBUILD
    (from rev 1276407, python-pythonfinder/trunk/PKGBUILD)
Deleted:
  python-pythonfinder/repos/community-any/PKGBUILD

----------+
 PKGBUILD |   78 +++++++++++++++++++++++++++++++------------------------------
 1 file changed, 40 insertions(+), 38 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-08-24 14:24:13 UTC (rev 1276407)
+++ PKGBUILD	2022-08-24 14:24:23 UTC (rev 1276408)
@@ -1,38 +0,0 @@
-# Maintainer: David Runge <dvzrv at archlinux.org>
-
-_name=pythonfinder
-pkgname=python-pythonfinder
-pkgver=1.2.10
-pkgrel=1
-pkgdesc="Cross Platform Search Tool for Finding Pythons"
-arch=(any)
-url="https://github.com/sarugaku/pythonfinder"
-license=(MIT)
-depends=(python-attrs python-cached-property python-click python-packaging python-six)
-makedepends=(python-setuptools)
-checkdepends=(python-pytest)
-# no tests in sdist tarballs on pypi.org
-# https://github.com/sarugaku/pythonfinder/issues/115
-# source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
-source=("$_name-$pkgver.tar.gz::https://github.com/sarugaku/$_name/archive/refs/tags/$pkgver.tar.gz")
-sha512sums=('ee01528cc70e2625868825bb25c6f8517d611c4c89da3357e48fd002faa5a9181f73774f2ed8e07be62ff08648bf0d16675ff06bab33f31993ac19ea0b5daf3f')
-b2sums=('c0cba99f9ff199f666ead89c367d141472479c459fd8c4b8c6f69182489c94bac4fa1c472052fecdb854b95483187412310ce03879c3ac99143e39a2224e930d')
-
-build() {
-  cd $_name-$pkgver
-  python setup.py build
-}
-
-check() {
-  cd $_name-$pkgver
-  export PYTHONPATH="$(pwd)/build/lib:$PYTHONPATH"
-  # disable tests that rely on git cloning: https://github.com/sarugaku/pythonfinder/issues/116
-  pytest -v -c /dev/null -k "not test_shims_are_kept and not test_shims_are_removed"
-}
-
-package() {
-  cd $_name-$pkgver
-  python setup.py install --optimize=1 --root="$pkgdir"
-  install -vDm 644 {CHANGELOG,README}.rst -t "$pkgdir/usr/share/doc/$pkgname/"
-  install -vDm 644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
-}

Copied: python-pythonfinder/repos/community-any/PKGBUILD (from rev 1276407, python-pythonfinder/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-08-24 14:24:23 UTC (rev 1276408)
@@ -0,0 +1,40 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=pythonfinder
+pkgname=python-pythonfinder
+pkgver=1.3.1
+pkgrel=1
+pkgdesc="Cross Platform Search Tool for Finding Pythons"
+arch=(any)
+url="https://github.com/sarugaku/pythonfinder"
+license=(MIT)
+depends=(python-attrs python-cached-property python-packaging)
+makedepends=(python-build python-installer python-setuptools python-wheel)
+checkdepends=(git python-click python-pytest)
+optdepends=('python-click: for CLI')
+source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
+sha512sums=('d1bc1dcf66b2052a547f4c5476149232249d33af1184b3e5188ff5d535912ce32653616b28961fdced6870fb086c05d32ef1f896cfa0b3babeb86b030429cbeb')
+b2sums=('067e5669d95907cc9b8cdd50d539838b9e56c65f83237f2dd6b7569b15f67e6e9c2513c9a1e87b139ce718be89e4587f8ef752098aa596d9a87e16a3875cc76a')
+
+build() {
+  cd $_name-$pkgver
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  local _site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
+
+  cd $_name-$pkgver
+  # install to temporary location, as importlib is used
+  python -m installer --destdir=test_dir dist/*.whl
+  export PYTHONPATH="test_dir/$_site_packages:$PYTHONPATH"
+  # disable tests that rely on git cloning: https://github.com/sarugaku/pythonfinder/issues/116
+  pytest -vv -c /dev/null -k "not test_shims_are_kept and not test_shims_are_removed"
+}
+
+package() {
+  cd $_name-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 {CHANGELOG,README}.rst -t "$pkgdir/usr/share/doc/$pkgname/"
+  install -vDm 644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
+}