[arch-commits] Commit in haskell-zip-archive/repos (2 files)

[Felix Yan]

    Date: Wednesday, August 24, 2022 @ 21:23:28
  Author: felixonmars
Revision: 1277269

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-zip-archive/repos/community-staging-x86_64/
  haskell-zip-archive/repos/community-staging-x86_64/PKGBUILD
    (from rev 1277268, haskell-zip-archive/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-zip-archive/repos/community-staging-x86_64/PKGBUILD (from rev 1277268, haskell-zip-archive/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-24 21:23:28 UTC (rev 1277269)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=zip-archive
+pkgname=haskell-zip-archive
+pkgver=0.4.2.1
+pkgrel=26
+pkgdesc="Library for creating and modifying zip archives."
+url="https://github.com/jgm/zip-archive"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-digest' 'haskell-old-time' 'haskell-temporary'
+         'haskell-zlib')
+makedepends=('ghc' 'haskell-hunit' 'unzip')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/jgm/zip-archive/archive/$pkgver.tar.gz")
+sha512sums=('dd47bd5804b707c91e208011a388f124fd7dff02678899687b49dcef186e8206d60d7fd155759a2a07eecaa6134821be8d79ff03fe3f20f5f54b587bc0325a45')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-executable -fsplitbase
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}