[arch-commits] Commit in haskell-websockets/repos (2 files)

[Felix Yan]

    Date: Wednesday, August 24, 2022 @ 22:09:27
  Author: felixonmars
Revision: 1277493

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-websockets/repos/community-staging-x86_64/
  haskell-websockets/repos/community-staging-x86_64/PKGBUILD
    (from rev 1277492, haskell-websockets/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-websockets/repos/community-staging-x86_64/PKGBUILD (from rev 1277492, haskell-websockets/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-24 22:09:27 UTC (rev 1277493)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=websockets
+pkgname=haskell-websockets
+pkgver=0.12.7.3
+pkgrel=52
+pkgdesc="A sensible and clean way to write WebSocket-capable servers in Haskell."
+url="https://hackage.haskell.org/package/${_hkgname}"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-attoparsec' 'haskell-base64-bytestring'
+         'haskell-case-insensitive' 'haskell-clock' 'haskell-entropy' 'haskell-network'
+         'haskell-random' 'haskell-sha' 'haskell-streaming-commons')
+makedepends=('ghc' 'uusi' 'haskell-hunit' 'haskell-test-framework' 'haskell-test-framework-hunit'
+             'haskell-test-framework-quickcheck2')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('9eb9147ff7b545c6e3e859055ff0ca51c16d7e2f0e8603279409b3e74db7ec858c33e586d8f40e3059ac8acf96d8c7502e1b5fe298d3d7fa4cad507e13a2b300')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    uusi -d bytestring-builder $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-Example
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENCE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENCE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENCE"
+}