[arch-commits] Commit in haskell-conduit-extra/repos (2 files)

[Felix Yan]

    Date: Friday, August 26, 2022 @ 16:19:36
  Author: felixonmars
Revision: 1283086

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-conduit-extra/repos/community-staging-x86_64/
  haskell-conduit-extra/repos/community-staging-x86_64/PKGBUILD
    (from rev 1283085, haskell-conduit-extra/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-conduit-extra/repos/community-staging-x86_64/PKGBUILD (from rev 1283085, haskell-conduit-extra/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-26 16:19:36 UTC (rev 1283086)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=conduit-extra
+pkgname=haskell-conduit-extra
+pkgver=1.3.6
+pkgrel=18
+pkgdesc="Batteries included conduit: adapters for common libraries."
+url="https://github.com/snoyberg/conduit"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-attoparsec' 'haskell-conduit' 'haskell-network'
+         'haskell-primitive' 'haskell-resourcet' 'haskell-streaming-commons' 'haskell-typed-process'
+         'haskell-unliftio-core')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hspec-discover' 'haskell-quickcheck'
+             'haskell-transformers-base')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('56f6abf0663734c0e40b3d21fed6d0942fe30acc8960105ac93ddbb15d10c9074213e0ead575cc4422824832beae026376d04a13f6a045efc2a695676cf03546')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}