[arch-commits] Commit in haskell-hackage-security/repos (2 files)

[Felix Yan]

    Date: Friday, August 26, 2022 @ 15:53:17
  Author: felixonmars
Revision: 1282957

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hackage-security/repos/community-staging-x86_64/
  haskell-hackage-security/repos/community-staging-x86_64/PKGBUILD
    (from rev 1282956, haskell-hackage-security/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: haskell-hackage-security/repos/community-staging-x86_64/PKGBUILD (from rev 1282956, haskell-hackage-security/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-26 15:53:17 UTC (rev 1282957)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hackage-security
+pkgname=haskell-hackage-security
+pkgver=0.6.2.0
+pkgrel=12
+pkgdesc="Hackage security library"
+url="https://github.com/well-typed/hackage-security"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base16-bytestring' 'haskell-base64-bytestring'
+         'haskell-cryptohash-sha256' 'haskell-ed25519' 'haskell-lukko' 'haskell-network'
+         'haskell-network-uri' 'haskell-tar' 'haskell-zlib')
+makedepends=('ghc' 'uusi' 'haskell-quickcheck' 'haskell-aeson' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck' 'haskell-temporary' 'haskell-unordered-containers'
+             'haskell-vector')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('1fdd5be9f01b8914a89853bc51a575c2d2efdf3b7811fdef130485cf2e95623cabeacac11861345ddd72fa65e6f80cf23576ef8786ba4a975bbabe64a307d768')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    uusi -d Cabal-syntax $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -fbase48 -fuse-network-uri -f-old-directory
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}