[arch-commits] Commit in lib32-libxml2/repos (2 files)

[Jan Steffens]

    Date: Friday, August 26, 2022 @ 21:47:04
  Author: heftig
Revision: 1284469

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-libxml2/repos/multilib-testing-x86_64/
  lib32-libxml2/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 1284468, lib32-libxml2/trunk/PKGBUILD)

----------+
 PKGBUILD |   68 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

Copied: lib32-libxml2/repos/multilib-testing-x86_64/PKGBUILD (from rev 1284468, lib32-libxml2/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2022-08-26 21:47:04 UTC (rev 1284469)
@@ -0,0 +1,68 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Tom Gundersen <teg at jklm.no>
+# Contributor: John Proctor <jproctor at prium.net>
+
+pkgbase=lib32-libxml2
+pkgname=(lib32-libxml2)
+pkgver=2.10.1
+pkgrel=1
+pkgdesc="XML C parser and toolkit (32-bit)"
+url="https://gitlab.gnome.org/GNOME/libxml2/-/wikis/home"
+arch=(x86_64)
+license=(custom:MIT)
+depends=(lib32-zlib lib32-xz lib32-icu libxml2)
+makedepends=(git)
+options=(debug)
+_commit=d85c4a01407b75eb4005256df106d121e766a1d8  # tags/v2.10.1^0
+source=("git+https://gitlab.gnome.org/GNOME/libxml2.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd libxml2
+  git describe --tags | sed 's/-rc/rc/;s/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd libxml2
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"
+
+  cd libxml2
+
+  ./configure \
+    --prefix=/usr \
+    --libdir=/usr/lib32 \
+    --with-threads \
+    --without-history \
+    --without-python \
+    --with-icu
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' libtool
+  make
+}
+
+check() {
+  cd libxml2
+  make check
+}
+
+package_lib32-libxml2() {
+  provides=(libxml2.so)
+
+  cd libxml2
+
+  make DESTDIR="$pkgdir" install
+
+  rm -r "$pkgdir"/usr/{include,share,bin}
+
+  install -Dm644 Copyright -t "$pkgdir/usr/share/licenses/$pkgname"
+}
+
+# vim:set sw=2 sts=-1 et: