[arch-commits] Commit in (4 files)

[Justin Kromlinger]

    Date: Monday, August 29, 2022 @ 13:48:30
  Author: hashworks
Revision: 1285194

Moved from AUR

Added:
  srs-state-threads/
  srs-state-threads/repos/
  srs-state-threads/trunk/
  srs-state-threads/trunk/PKGBUILD

----------+
 PKGBUILD |   34 ++++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)

Added: srs-state-threads/trunk/PKGBUILD
===================================================================
--- srs-state-threads/trunk/PKGBUILD	                        (rev 0)
+++ srs-state-threads/trunk/PKGBUILD	2022-08-29 13:48:30 UTC (rev 1285194)
@@ -0,0 +1,34 @@
+# Maintainer: Justin Kromlinger <hashworks at archlinux.org>
+# Contributor: heinrich5991 <heinrich5991 at gmail.com>
+
+pkgname=srs-state-threads
+pkgver=1.9.3
+pkgrel=2
+pkgdesc="Fork of state-threads, patched for SRS"
+_pkgcommit=bb94c45ac58bfe54d6544071da936be4d4e04dd1
+arch=('x86_64')
+url="https://github.com/ossrs/state-threads/"
+license=('GPL2' 'MPL')
+makedepends=('git')
+source=("git+https://github.com/ossrs/state-threads/#commit=${_pkgcommit}")
+sha256sums=('SKIP')
+
+prepare() {
+  cd "${srcdir}"/state-threads
+  ldFlags="$(echo "$LDFLAGS" | sed 's|-Wl,||;s|,| |g') -z noexecstack"
+  sed -ie "s|LDFLAGS     =|LDFLAGS     = ${ldFlags}|" Makefile
+}
+
+build() {
+  cd "${srcdir}"/state-threads
+  make STATIC_ONLY=no linux-optimized
+}
+
+package() {
+  cd "${srcdir}"/state-threads/obj
+  install -Dm644 st.h "${pkgdir}"/usr/include/st.h
+  install -Dm644 libst.a "${pkgdir}"/usr/lib/libst.a
+  install -Dm755 libst.so.1.9 "${pkgdir}"/usr/lib/libst.so.1.9
+  ln -s libst.so.1.9 "${pkgdir}"/usr/lib/libst.so.1
+  ln -s libst.so.1.9 "${pkgdir}"/usr/lib/libst.so
+}