[arch-commits] Commit in lib32-libxslt/repos (2 files)
Jan Steffens
heftig at gemini.archlinux.org
Mon Aug 29 16:21:52 UTC 2022
Date: Monday, August 29, 2022 @ 16:21:51
Author: heftig
Revision: 1285396
archrelease: copy trunk to multilib-testing-x86_64
Added:
lib32-libxslt/repos/multilib-testing-x86_64/
lib32-libxslt/repos/multilib-testing-x86_64/PKGBUILD
(from rev 1285395, lib32-libxslt/trunk/PKGBUILD)
----------+
PKGBUILD | 80 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 80 insertions(+)
Copied: lib32-libxslt/repos/multilib-testing-x86_64/PKGBUILD (from rev 1285395, lib32-libxslt/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD (rev 0)
+++ multilib-testing-x86_64/PKGBUILD 2022-08-29 16:21:51 UTC (rev 1285396)
@@ -0,0 +1,80 @@
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+# Contributor: Eric Belanger <eric at archlinux.org>
+# Contributor: John Proctor <jproctor at prium.net>
+
+pkgbase=lib32-libxslt
+pkgname=(lib32-libxslt)
+pkgver=1.1.37
+pkgrel=1
+pkgdesc="XML stylesheet transformation library (32-bit)"
+url="https://gitlab.gnome.org/GNOME/libxslt/-/wikis/home"
+arch=(x86_64)
+license=(custom:MIT)
+depends=(
+ lib32-libgcrypt
+ lib32-libxml2
+ lib32-xz
+ libxslt
+)
+makedepends=(
+ git
+)
+checkdepends=(
+ docbook-xml
+ python
+)
+options=(debug)
+_commit=5eca7fb65b7337409a02f9f94fde608edf7d1b0a # tags/v1.1.37^0
+source=("git+https://gitlab.gnome.org/GNOME/libxslt.git#commit=$_commit"
+ 0001-Make-generate-id-deterministic.patch)
+sha256sums=('SKIP'
+ '605e0a0b2ca385a90226bc5b141d3f6bfeade13e43ab39f8dea863505d7cbf18')
+
+pkgver() {
+ cd libxslt
+ git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+ cd libxslt
+
+ # Make xsltproc output reproducible for packages which use it to generate documentation
+ git apply -3 ../0001-Make-generate-id-deterministic.patch
+
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ export CC="gcc -m32"
+ export CXX="g++ -m32"
+ export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"
+
+ cd libxslt
+
+ ./configure \
+ --prefix=/usr \
+ --libdir=/usr/lib32 \
+ --without-python \
+ --disable-static
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' libtool
+ make
+}
+
+check() {
+ cd libxslt
+ make check
+}
+
+package_lib32-libxslt() {
+ provides=(lib{,e}xslt.so)
+
+ cd libxslt
+
+ make DESTDIR="$pkgdir" install
+
+ rm -r "$pkgdir"/usr/{include,share,bin}
+
+ install -Dm644 Copyright -t "$pkgdir/usr/share/licenses/$pkgname"
+}
+
+# vim:set sw=2 sts=-1 et:
More information about the arch-commits
mailing list