[arch-commits] Commit in haskell-mustache/repos (2 files)

[Felix Yan]

    Date: Tuesday, August 30, 2022 @ 17:26:21
  Author: felixonmars
Revision: 1288874

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-mustache/repos/community-staging-x86_64/
  haskell-mustache/repos/community-staging-x86_64/PKGBUILD
    (from rev 1288873, haskell-mustache/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-mustache/repos/community-staging-x86_64/PKGBUILD (from rev 1288873, haskell-mustache/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-30 17:26:21 UTC (rev 1288874)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=mustache
+pkgname=haskell-mustache
+pkgver=2.4.1
+pkgrel=64
+pkgdesc="A mustache template parser library."
+url="https://github.com/JustusAdam/mustache"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-unordered-containers' 'haskell-vector'
+         'haskell-scientific' 'haskell-th-lift' 'haskell-cmdargs' 'haskell-yaml')
+makedepends=('ghc' 'haskell-hspec' 'haskell-base-unicode-symbols' 'haskell-wreq' 'haskell-zlib'
+             'haskell-tar' 'haskell-lens' 'haskell-temporary')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('389a418712fee9ff16c88f45014470e1cdd31f6e9dd2f418853a1a2d174ba7fd11ee05ba20f22b134d34b95377bf55c5add5b52cf423ecb49338bd4ff6534e13')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}