[arch-commits] Commit in haskell-doctest/repos (2 files)

[Felix Yan]

    Date: Wednesday, February 2, 2022 @ 00:26:43
  Author: felixonmars
Revision: 1122294

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-doctest/repos/community-staging-x86_64/
  haskell-doctest/repos/community-staging-x86_64/PKGBUILD
    (from rev 1122293, haskell-doctest/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: haskell-doctest/repos/community-staging-x86_64/PKGBUILD (from rev 1122293, haskell-doctest/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-02-02 00:26:43 UTC (rev 1122294)
@@ -0,0 +1,58 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=doctest
+pkgname=haskell-doctest
+pkgver=0.18.2
+pkgrel=35
+pkgdesc="Test interactive Haskell examples"
+url="https://github.com/sol/doctest"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-compat' 'haskell-exceptions' 'haskell-ghc' 'haskell-syb'
+         'haskell-code-page' 'haskell-ghc-paths')
+makedepends=('ghc')
+checkdepends=('haskell-hunit' 'haskell-hspec' 'haskell-hspec-core' 'haskell-quickcheck'
+              'haskell-stringbuilder' 'haskell-silently' 'haskell-setenv' 'haskell-mockery')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('fd6c9d5b3292083ec3d9301779c0d165879cea0b71d5548cd49e6394f6eaf908679312f1ed9606298966169cd383886df18fb292e15a4132c1567f4c46782b83')
+
+prepare() {
+    # Add -dynamic flag
+    sed -i 's/\+\+ packageDBArgs/++ packageDBArgs ++ ["-dynamic"]/' $_hkgname-$pkgver/src/Extract.hs
+    sed -i 's/\+\+ expandedArgs)/++ expandedArgs ++ ["-dynamic"])/' $_hkgname-$pkgver/src/Run.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    if (( CHECKFUNC )); then
+        _opts=('--enable-tests')
+    else
+        _opts=('--disable-tests')
+    fi
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname "${_opts[@]}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test || echo "Tests failed"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}