[arch-commits] Commit in gdbm/repos (testing-x86_64 testing-x86_64/PKGBUILD)
David Runge
dvzrv at gemini.archlinux.org
Fri Feb 4 21:33:02 UTC 2022
Date: Friday, February 4, 2022 @ 21:33:02
Author: dvzrv
Revision: 436216
archrelease: copy trunk to testing-x86_64
Added:
gdbm/repos/testing-x86_64/
gdbm/repos/testing-x86_64/PKGBUILD
(from rev 436215, gdbm/trunk/PKGBUILD)
----------+
PKGBUILD | 46 ++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 46 insertions(+)
Copied: gdbm/repos/testing-x86_64/PKGBUILD (from rev 436215, gdbm/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2022-02-04 21:33:02 UTC (rev 436216)
@@ -0,0 +1,46 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: judd <jvinet at zeroflux.org>
+
+pkgname=gdbm
+pkgver=1.23
+pkgrel=1
+pkgdesc="GNU database library"
+arch=(x86_64)
+url="https://www.gnu.org/software/gdbm/gdbm.html"
+license=(GPL3)
+depends=(glibc sh)
+makedepends=(readline)
+provides=(libgdbm_compat.so libgdbm.so)
+options=(debug)
+source=("https://ftp.gnu.org/gnu/gdbm/$pkgname-$pkgver.tar.gz"{,.sig})
+sha512sums=('918080cb0225b221c11eb7339634a95e00c526072395f7a3d46ccf42ef020dea7c4c5bec34aff2c4f16033e1fff6583252b7e978f68b8d7f8736b0e025838e10'
+ 'SKIP')
+b2sums=('a47746577cf2f3c9b62faea496c4d6a50a8f1b0a5af448cb2215e90057c99b5b630ba3f5357c85dfb7fd98ba4e90969e30a779120c29106ed1e8736721f9bec1'
+ 'SKIP')
+validpgpkeys=('325F650C4C2B6AD58807327A3602B07F55D0C732') # Sergey Poznyakoff <gray at gnu.org>
+
+prepare() {
+ cd $pkgname-$pkgver
+ autoreconf -fiv
+}
+
+build() {
+ cd $pkgname-$pkgver
+ ./configure --prefix=/usr \
+ --enable-libgdbm-compat
+ make
+}
+
+check() {
+ make check -C $pkgname-$pkgver
+}
+
+package() {
+ depends+=(libreadline.so)
+
+ make DESTDIR="$pkgdir" install -C $pkgname-$pkgver
+ install -vDm 644 $pkgname-$pkgver/{NOTE-WARNING,AUTHORS,NEWS,README,ChangeLog} -t "$pkgdir/usr/share/doc/$pkgname"
+}
More information about the arch-commits
mailing list