[arch-commits] Commit in haskell-aeson-diff/repos (2 files)

[Felix Yan]

    Date: Friday, February 4, 2022 @ 22:38:20
  Author: felixonmars
Revision: 1126214

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-aeson-diff/repos/community-staging-x86_64/
  haskell-aeson-diff/repos/community-staging-x86_64/PKGBUILD
    (from rev 1126213, haskell-aeson-diff/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-aeson-diff/repos/community-staging-x86_64/PKGBUILD (from rev 1126213, haskell-aeson-diff/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-02-04 22:38:20 UTC (rev 1126214)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=aeson-diff
+pkgname=haskell-aeson-diff
+pkgver=1.1.0.9
+pkgrel=261
+pkgdesc="Extract and apply patches to JSON documents"
+url="https://github.com/thsutton/aeson-diff"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-edit-distance-vector' 'haskell-hashable'
+         'haskell-scientific' 'haskell-unordered-containers' 'haskell-vector'
+         'haskell-optparse-applicative')
+makedepends=('ghc' 'uusi' 'haskell-doctest' 'haskell-glob' 'haskell-quickcheck'
+             'haskell-quickcheck-instances' 'hlint')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('2778eabe53ac0520028c9eccae7f52dcdeb2eccb4df4ff6a84e4625afc5d46533ebf61b6b99c16eb5ffe9792e781b0f9a8e1e43c2b69b751d1dbc5dd627635d9')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    uusi -u base $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}