[arch-commits] Commit in mako/repos (3 files)

[Brett Cornwall]

    Date: Saturday, February 5, 2022 @ 04:18:39
  Author: ainola
Revision: 1126381

archrelease: copy trunk to community-testing-x86_64

Added:
  mako/repos/community-testing-x86_64/
  mako/repos/community-testing-x86_64/PKGBUILD
    (from rev 1126380, mako/trunk/PKGBUILD)
  mako/repos/community-testing-x86_64/systemd-dbus-activation.patch
    (from rev 1126380, mako/trunk/systemd-dbus-activation.patch)

-------------------------------+
 PKGBUILD                      |   44 ++++++++++++++++++++++++++++++++++++++++
 systemd-dbus-activation.patch |    7 ++++++
 2 files changed, 51 insertions(+)

Copied: mako/repos/community-testing-x86_64/PKGBUILD (from rev 1126380, mako/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-02-05 04:18:39 UTC (rev 1126381)
@@ -0,0 +1,44 @@
+# Maintainer: Brett Cornwall <ainola at archlinux.org>
+# Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
+# Contributor: Drew DeVault
+
+pkgname=mako
+pkgver=1.6
+pkgrel=3
+license=('MIT')
+pkgdesc='Lightweight notification daemon for Wayland'
+makedepends=("meson" "scdoc" "systemd" "wayland-protocols")
+depends=(
+	"gdk-pixbuf2"
+	"pango"
+	"systemd-libs"
+	"wayland"
+)
+optdepends=("jq: support for 'makoctl menu'")
+arch=("x86_64")
+url='https://mako-project.org'
+options=(debug)
+source=(
+	"$pkgname-$pkgver.tar.gz::https://github.com/emersion/mako/releases/download/v$pkgver/mako-$pkgver.tar.gz"
+	"$pkgname-$pkgver.tar.gz.sig::https://github.com/emersion/mako/releases/download/v$pkgver/mako-$pkgver.tar.gz.sig"
+	"systemd-dbus-activation.patch"
+)
+validpgpkeys=("34FF9526CFEF0E97A340E2E40FDE7BE0E88F5E48") # emersion
+sha256sums=('9f43cba9e1b43c69be8c9e4a79c358b3cd22153ca3ffb8bf0ee7aa30c59b2fc2'
+            'SKIP'
+            '4579a2673dcf2114779e10ed52d771f3930c2192e8e35d3e145163d9e0b45c20')
+
+prepare() {
+	patch -Np1 -i "$srcdir/systemd-dbus-activation.patch" -d "$pkgname-$pkgver"
+}
+
+build() {
+	arch-meson -Dzsh-completions=true -Dsd-bus-provider=libsystemd "$pkgname-$pkgver" build
+	ninja -C build
+}
+
+package() {
+	DESTDIR="$pkgdir" ninja -C build install
+	install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" "$pkgname-$pkgver/LICENSE"
+	install -Dm644 -t "$pkgdir/usr/lib/systemd/user/" "$pkgname-$pkgver/contrib/systemd/mako.service"
+}

Copied: mako/repos/community-testing-x86_64/systemd-dbus-activation.patch (from rev 1126380, mako/trunk/systemd-dbus-activation.patch)
===================================================================
--- community-testing-x86_64/systemd-dbus-activation.patch	                        (rev 0)
+++ community-testing-x86_64/systemd-dbus-activation.patch	2022-02-05 04:18:39 UTC (rev 1126381)
@@ -0,0 +1,7 @@
+--- a/fr.emersion.mako.service.in
++++ b/fr.emersion.mako.service.in
+@@ -1,3 +1,4 @@
+ [D-BUS Service]
+ Name=org.freedesktop.Notifications
+ Exec=@bindir@/mako
++SystemdService=mako.service