[arch-commits] Commit in foot/repos (2 files)
Caleb Maclennan
alerque at gemini.archlinux.org
Sat Feb 5 20:50:26 UTC 2022
Date: Saturday, February 5, 2022 @ 20:50:26
Author: alerque
Revision: 1126890
archrelease: copy trunk to community-staging-x86_64
Added:
foot/repos/community-staging-x86_64/
foot/repos/community-staging-x86_64/PKGBUILD
(from rev 1126889, foot/trunk/PKGBUILD)
----------+
PKGBUILD | 70 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 70 insertions(+)
Copied: foot/repos/community-staging-x86_64/PKGBUILD (from rev 1126889, foot/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-02-05 20:50:26 UTC (rev 1126890)
@@ -0,0 +1,70 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Daniel Eklöf <daniel at ekloef dot se>
+
+pkgbase=foot
+pkgdesc='Fast, lightweight, and minimalistic Wayland terminal emulator'
+pkgname=($pkgbase $pkgbase-terminfo)
+pkgver=1.11.0
+pkgrel=1
+url="https://codeberg.org/dnkl/$pkgbase"
+arch=(x86_64)
+license=(MIT)
+makedepends=(fcft
+ fontconfig
+ libutf8proc
+ libxkbcommon
+ llvm
+ meson
+ ncurses
+ ninja
+ pixman
+ python
+ scdoc
+ sway
+ tllist
+ wayland
+ wayland-protocols)
+options=(debug)
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+sha256sums=('2b4f737eb4d266224e5dd0126168c6d770b0139d4b572078baf158d2f7166e4e')
+
+build() {
+ cd "$pkgbase"
+ ./pgo/pgo.sh \
+ full-headless-sway \
+ . build \
+ -Dterminfo=disabled \
+ --prefix=/usr \
+ --wrap-mode=nodownload
+ sed 's/@default_terminfo@/foot-extra/g' foot.info |
+ tic -x -o build -e foot-extra,foot-extra-direct -
+}
+
+check() {
+ cd "$pkgbase"
+ ninja -C build test
+}
+
+package_foot() {
+ optdepends=('foot-terminfo: exta non-standard features over terminfo included in ncurses'
+ 'libnotify: desktop notifications'
+ 'xdg-utils: URI launching')
+ depends=(fcft
+ fontconfig
+ libutf8proc
+ libxkbcommon
+ ncurses
+ pixman
+ wayland)
+ cd "$pkgbase"
+ DESTDIR="$pkgdir" ninja -C build install
+ install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}
+
+package_foot-terminfo() {
+ pkgdesc="Extra non-standard terminfo files for $pkgbase, a Wayland terminal emulator"
+ depends=(ncurses)
+ cd "$pkgbase"
+ install -Dm0644 -t "$pkgdir/usr/share/terminfo/f/" build/f/foot-extra*
+ install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}
More information about the arch-commits
mailing list