[arch-commits] Commit in haskell-quickcheck-instances/repos (2 files)

[Felix Yan]

    Date: Monday, February 7, 2022 @ 20:10:43
  Author: felixonmars
Revision: 1128694

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-quickcheck-instances/repos/community-staging-x86_64/
  haskell-quickcheck-instances/repos/community-staging-x86_64/PKGBUILD
    (from rev 1128693, haskell-quickcheck-instances/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-quickcheck-instances/repos/community-staging-x86_64/PKGBUILD (from rev 1128693, haskell-quickcheck-instances/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-02-07 20:10:43 UTC (rev 1128694)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=quickcheck-instances
+pkgname=haskell-quickcheck-instances
+pkgver=0.3.26
+pkgrel=2
+pkgdesc="Common quickcheck instances"
+url="https://github.com/haskellari/qc-instances"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-onetuple' 'haskell-quickcheck' 'haskell-case-insensitive'
+         'haskell-data-fix' 'haskell-hashable' 'haskell-integer-logarithms' 'haskell-old-time'
+         'haskell-scientific' 'haskell-splitmix' 'haskell-strict' 'haskell-tagged'
+         'haskell-text-short' 'haskell-these' 'haskell-time-compat' 'haskell-transformers-compat'
+         'haskell-unordered-containers' 'haskell-uuid-types' 'haskell-vector')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('3d961c017c18181907c7b85f7354f399a2bae7738c68a7a9b613b3a69cdd39922ec0e2d9a749d6ed9033a7a9535adb766e094b9bc35c4dec36fbd348fa291d90')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-bytestring-builder
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}