[arch-commits] Commit in tectonic/repos (community-x86_64 community-x86_64/PKGBUILD)

[Frederik Schwan]

    Date: Tuesday, February 8, 2022 @ 15:17:42
  Author: freswa
Revision: 1129241

archrelease: copy trunk to community-x86_64

Added:
  tectonic/repos/community-x86_64/
  tectonic/repos/community-x86_64/PKGBUILD
    (from rev 1129240, tectonic/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: tectonic/repos/community-x86_64/PKGBUILD (from rev 1129240, tectonic/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2022-02-08 15:17:42 UTC (rev 1129241)
@@ -0,0 +1,41 @@
+# Maintainer: Frederik Schwan <freswa at archlinux dot org>
+# Contributor: tectonic-deploy <sasha+tectonic at hackafe.net>
+# Contributor: Daniel M. Capella <polyzen at archlinux.org>
+# Contributor: Jan Tojnar <jtojnar at gmail.com>
+
+pkgname=tectonic
+pkgver=0.8.0
+pkgrel=2
+pkgdesc='Modernized, complete, self-contained TeX/LaTeX engine, powered by XeTeX and TeXLive'
+arch=('x86_64')
+url='https://tectonic-typesetting.github.io/'
+license=('MIT')
+depends=('fontconfig' 'harfbuzz-icu' 'openssl')
+makedepends=('cargo' 'pkg-config')
+options=(!lto)
+source=("https://github.com/tectonic-typesetting/tectonic/archive/refs/tags/tectonic@${pkgver}.tar.gz")
+b2sums=('7587760d15b913ad0afe02d7087b32a311a88076cdb2894a8de64027a112b419eeb5cd1e908869e4ad542dd784b192fd36ddc76f95d692eefa1e45fe59e43352')
+
+prepare() {
+  cd ${pkgname}-${pkgname}-${pkgver}
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd ${pkgname}-${pkgname}-${pkgver}
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  cargo build --release --locked --features external-harfbuzz
+}
+
+check() {
+  cd ${pkgname}-${pkgname}-${pkgver}
+  export RUSTUP_TOOLCHAIN=stable
+  cargo test --release --locked --features external-harfbuzz
+}
+
+package() {
+  cd ${pkgname}-${pkgname}-${pkgver}
+  install -Dm755 target/release/tectonic "${pkgdir}"/usr/bin/tectonic
+  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}